File Coverage

blib/lib/Tie/Redis/Candy/Array.pm

Criterion	Covered	Total	%
statement	36	39	92.3
branch	5	8	62.5
condition			n/a
subroutine	14	17	82.3
pod			n/a
total	55	64	85.9

# This file was part of Redis, licensed under:
#
#   The Artistic License 2.0 (GPL Compatible)
#
# Copyright (c) 2015 by Pedro Melo, Damien Krotkine.

use strictures 2;

package Tie::Redis::Candy::Array;

# ABSTRACT: tie Perl arrays to Redis lists - the candy way

use Carp qw(croak confess);
use CBOR::XS qw(encode_cbor decode_cbor);
use base 'Tie::Array';

my $undef = encode_cbor(undef);

our $VERSION = '1.001';    # VERSION

sub TIEARRAY {
    my ( $class, $redis, $listname ) = @_;

    croak "not a Redis instance: $redis"
      unless ref($redis) =~ m{^(?:Test::Mock::)?Redis$};

    my $self = {
        list  => $listname,
        redis => $redis,
    };

    return bless( $self, $class );
}

sub FETCH {
    my ( $self, $index ) = @_;
    my $data = $self->{redis}->lindex( $self->{list}, $index );
    return unless defined $data;
    decode_cbor($data);
}

sub FETCHSIZE {
    my ($self) = @_;
    $self->{redis}->llen( $self->{list} );
}

sub STORE {
    my ( $self, $index, $value ) = @_;
    $self->{redis}->lset( $self->{list}, $index, encode_cbor($value) );
}

sub STORESIZE {
    my ( $self, $count ) = @_;
    $self->{redis}->ltrim( $self->{list}, 0, $count );
}

sub CLEAR {
    my ($self) = @_;
    $self->{redis}->del( $self->{list} );
}

sub PUSH {
    my ( $self, @values ) = @_;
    $self->{redis}->rpush( $self->{list}, encode_cbor($_) ) for @values;
}

sub POP {
    my ($self) = @_;
    map { defined($_) ? decode_cbor($_) : undef }
      $self->{redis}->rpop( $self->{list} );
}

sub SHIFT {
    my ($self) = @_;
    map { defined($_) ? decode_cbor($_) : undef }
      $self->{redis}->lpop( $self->{list} );
}

sub UNSHIFT {
    my ( $self, @values ) = @_;
    $self->{redis}->lpush( $self->{list}, encode_cbor($_) ) for reverse @values;
}

sub SPLICE {
    confess 'UNIMPLEMENTED';
}

sub EXTEND {
}

sub DESTROY {
}

1;

__END__