File Coverage

blib/lib/Throwable/SysError.pm

Criterion	Covered	Total	%
statement	18	18	100.0
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod	1	1	100.0
total	25	25	100.0

package Throwable::SysError;

use namespace::autoclean;
use Errno qw();
use Moo;
use MooX::Types::MooseLike::Base qw( Int Str );
use Scalar::Util qw();

extends qw( Throwable::Error );

our $VERSION = '0.00';


has op     => ( is => 'ro', isa => Str, required => 1 );
has errno  => ( is => 'ro', isa => Int, required => 1 );
has errstr => ( is => 'ro', isa => Str, required => 1 );


around BUILDARGS => sub {
  my ( $orig, $class ) = ( shift, shift );

  my $args   = $class->$orig( @_ );
  my $_errno = defined $args->{_errno}
    ? do { local $! = $args->{_errno}; $! }
    : $!
  ;

  @$args{qw( errno errstr )}
    = ( 0 + $_errno, ''. $_errno );

  $args
};

around throw => sub {
  my ( $orig, $invocant ) = ( shift, shift );

  # save $! as soon as possible
  my $_errno = $!;

  # pass-through on re-throw
  return $invocant->$orig( @_ )
    if Scalar::Util::blessed( $invocant );

  # fix up @_ to include _errno
  if( @_ == 1 ) {
    # inject _errno if we have a single hash argument.
    # otherwise we don't know what to do.
    $_[0]->{_errno} = $_errno
      if ref $_[0] eq 'HASH' && ! defined $_[0]->{_errno};
  }
  else {
    # inject _errno at the front of the list to allow
    # overriding when in new()
    unshift @_, _errno => $_errno;
  }

  $invocant->$orig( @_ )
};

sub is {
  my ( $self, $errname ) = @_;

  local $! = $self->errno;
  $!{$errname}
}


1
__END__