File Coverage

blib/lib/Throttle/Adaptive.pm

Criterion	Covered	Total	%
statement	28	32	87.5
branch	4	6	66.6
condition	3	7	42.8
subroutine	7	7	100.0
pod	2	3	66.6
total	44	55	80.0

use strict;
use warnings;
package Throttle::Adaptive;
our $AUTHORITY = 'cpan:TVDW';
$Throttle::Adaptive::VERSION = '0.001';
# ABSTRACT: implementation of the "adaptive throttling" algorithm by Google

use Time::HiRes qw/CLOCK_MONOTONIC/;

sub new {
    my ($class, %args)= @_;
    return bless {
        ratio => $args{ratio} || 2,
        time => $args{time} || 120,

        window => [],
        window_success => 0,
        window_total => 0,
    }, $class;
}

sub _process_window {
    my ($self)= @_;
    my $now= Time::HiRes::clock_gettime(CLOCK_MONOTONIC);
    while (@{$self->{window}} && $self->{window}[0][0] < $now) {
        my $entry= shift @{$self->{window}};
        $self->{window_total}--;
        $self->{window_success}-- if $entry->[1];
    }
    return;
}

sub should_fail {
    my ($self)= @_;
    $self->_process_window;

    my $fail= ( rand() < (($self->{window_total} - ($self->{ratio} * $self->{window_success})) / ($self->{window_total} + 1)) );
    $self->count(1) if $fail;
    return $fail;
}

sub count {
    my ($self, $error)= @_;
    my $success= !$error;

    $self->{window_total}++;
    push @{$self->{window}}, [ Time::HiRes::clock_gettime(CLOCK_MONOTONIC)+$self->{time}, $success ];
    $self->{window_success}++ if $success;
    return;
}

1;

__END__