File Coverage

blib/lib/Text/Template/Inline.pm

Criterion	Covered	Total	%
statement	53	53	100.0
branch	19	20	95.0
condition	6	6	100.0
subroutine	10	10	100.0
pod	1	1	100.0
total	89	90	98.8

package Text::Template::Inline;
use strict;
use warnings;
use base 'Exporter';
our @EXPORT = qw/ render /;

use Carp qw/ croak /;
use Scalar::Util qw/ blessed reftype /;

our $VERSION = '0.13';

#
# The import function accepts an alternate name for the "render" function,
# then aliases and exports that name instead of the original.
#
sub import {
    my ($package, $func_name) = @_;
    local @EXPORT = @EXPORT;
    if ($func_name) {
        # export the provided name instead of "render"
        @EXPORT = ($func_name);
        no strict 'refs';
        *{$func_name} = *render;
    }
    $package->export_to_level(1,@_);
}

#
# This function is the only external module interface.
# If you don't like the name, just import a better one!
#
sub render ($$) {
    my ($data, $template) = @_;
    return $template unless $template;

    # Trim leading whitespace, preserving relative indent.
    # There's no way to know what your tabstops are, so we have to
    # assume that you indent consistently w/ regards to tabs/spaces.
    my $indent;
    while ($template =~ m/^([\t ]+)/mg) {
        my $lead = length $1;
        $indent = (defined $indent && $lead > $indent) ? $indent : $lead;
    }
    $template =~ s/^[\t ]{$indent}//mg if defined $indent;
    $template =~ s/^\n//; # remove leading newline

    # perform the data substitutions
    $template =~ s/(\{(\w[.\w]*)\})/_traverse_ref_with_path($data,$2,$1)/ge;

    return $template;
}

#
# This function dissects a period-delimited path of keys and follows them,
# traversing $theref. If the appropriate field exists at each level the final
# value is returned. If any field is not found, $default is returned.
#
sub _traverse_ref_with_path {
    my ($theref, $path, $default) = @_;
    my @keys = split /\./, $path;
    my $ref = $theref;
    for my $key (@keys) {
        no warnings 'uninitialized'; # for comparisons involving a non-ref $ref
        if (blessed $ref) {
            return $default unless $ref->can($key);
            $ref = $ref->$key();
        }
        elsif (reftype $ref eq 'HASH') {
            return $default unless exists $ref->{$key};
            $ref = $ref->{$key};
        }
        elsif (reftype $ref eq 'ARRAY') {
            return $default unless $key =~ /^\d+$/ and exists $ref->[$key];
            $ref = $ref->[$key];
        }
        else {
            local $Carp::CarpLevel = 2;
            croak "unable to use scalar '$theref' as template data";
        }
    }
    return $ref;
}

1;
__END__