File Coverage

blib/lib/Text/Outdent.pm

Criterion	Covered	Total	%
statement	44	45	97.7
branch	5	10	50.0
condition			n/a
subroutine	9	10	90.0
pod	4	7	57.1
total	62	72	86.1

package Text::Outdent;
use 5.006;

$VERSION = 0.01;
@EXPORT_OK = qw/
    outdent
    outdent_all
    outdent_quote
    expand_leading_tabs
/;
$EXPORT_TAGS{ALL} = \@EXPORT_OK;

use strict;
use base 'Exporter';

{
    my $indent_re = qr/^([^\S\n]*(?=\S))/m;
    sub find_indention {
        my ($str) = @_;

        return '' if $str !~ /\S/;

        $str =~ /$indent_re/g;
        my $i = $1;
        return '' if not length $i;

        while ($str =~ /$indent_re/g) {
            my $i2 = $1;
            ($i) = "$i\n$i2" =~ /^(.*).*\n\1/;
            return '' if not length $i2;
        }
        return $i;
    }
}

{
    my $indent_re = qr/^(?!$)([^\S\n]*)/m;
    sub find_indention_all {
        my ($str) = @_;

        $str =~ /$indent_re/g;
        my $i = $1;
        return '' if not length $i;

        while ($str =~ /$indent_re/g) {
            my $i2 = $1;
            ($i) = "$i\n$i2" =~ /^(.*).*\n\1/;
            return '' if not length $i2;
        }
        return $i;
    }
}

sub outdent_all {
    my ($str) = @_;

    my $indent = find_indention_all($str);
    $str =~ s/^$indent//gm;

    return $str;
}

sub outdent {
    my ($str) = @_;

    my $indent = find_indention($str);
    $str =~ s/^$indent(?=.*?\S)//gm;

    return $str;
}

# Removes any leading whitespaces uptil and including the first whitespace.
# Removes any trailing whitespaces if they come directly after a newline.
# (In this paragraph "whitespace" excludes newline.)
sub heredocify {
    my ($str) = @_;

    $str =~ s/^[^\S\n]*\n//;
    $str =~ s/^[^\S\n]+\z//m;

    return $str;
}

sub outdent_quote { outdent(heredocify($_[0])) }

sub expand_leading_tabs {
    my ($tabstop, $str) = @_;

    1 while $str =~ s{
        ^ ([^\S\t\n]*?) (\t+)
    }{
        $1 . ' ' x ($tabstop * length($2) - length($1) % $tabstop)
    }gemx;

    return $str;
}

1;

__END__