File Coverage

blib/lib/Text/Markup/Any.pm

Criterion	Covered	Total	%
statement	40	48	83.3
branch	15	28	53.5
condition	3	8	37.5
subroutine	9	9	100.0
pod	0	4	0.0
total	67	97	69.0

package Text::Markup::Any;
use strict;
use warnings;
use utf8;
our $VERSION = '0.04';

use parent 'Exporter';
use Class::Load qw/load_class/;

our @EXPORT = qw/markupper/;

my $markdown = {markup_method   => 'markdown'};
our %MODULES = (
    'Text::Markdown'            => $markdown,
    'Text::MultiMarkdown'       => $markdown,
    'Text::Markdown::Discount'  => $markdown,
    'Text::Markdown::GitHubAPI' => $markdown,
    'Text::Markdown::Hoedown' => {
        class         => 'Text::Markdown::Hoedown::Markdown',
        markup_method => 'render',
        args          => sub { [0, 16, Text::Markdown::Hoedown::Renderer::HTML->new(0, 99)] },
        deref         => 1,
    },
    'Text::Xatena'              => {markup_method => 'format'},
    'Text::Textile'             => {markup_method => 'process'},
);

sub new {
    my ($pkg, $class, @args) = @_;

    my $args;
    if (@args) {
        $args = ref $args[0] ? $args[0] : {@args};
    }

    my $info = $MODULES{$class}
        or die "no configuration found: $class. You want to use $class, directory call $pkg->adaptor constractor.";

    if ($args) {
        if ($info->{args} && ref($info->{args}) eq 'HASH') {
            $info->{args} = {
                %{ $info->{args} },
                %$args,
            };
        }
        else {
            $info->{args} = $args;
        }
    }

    load_class($class) if $info->{class};
    $pkg->adaptor(
        class   => $class,
        %$info,
    );
}

# taken from Ark::Models
sub adaptor {
    my ($pkg, %info) = @_;

    my $class         = $info{class} or die q{Required class parameter};
    my $markup_method = $info{markup_method} or die q{Required markup_method parameter};
    my $constructor   = $info{constructor} || 'new';

    load_class($class);
    $info{args} = $info{args}->() if ref $info{args} eq 'CODE';

    my $instance;
    if ($info{deref} and my $args = $info{args}) {
        if (ref($args) eq 'HASH') {
            $instance = $class->$constructor(%$args);
        }
        elsif (ref($args) eq 'ARRAY') {
            $instance = $class->$constructor(@$args);
        }
        else {
            die qq{Couldn't dereference: $args};
        }
    }
    elsif ($info{args}) {
        $instance = $class->$constructor($info{args});
    }
    else {
        $instance = $class->$constructor;
    }

    bless {
        _instance      => $instance,
        _markup_method => $markup_method,
    }, $pkg;
}

sub markup {
    my ($self, @text) = @_;

    my $meth = $self->{_markup_method};
    $self->{_instance}->$meth(@text);
}

sub markupper {
    my $class = shift;
    $class = "Text::$class" unless $class =~ /^\+/;

    __PACKAGE__->new($class, @_);
}


1;
__END__