File Coverage

blib/lib/Text/Hunspell/FFI.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	6	10	60.0
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	45	49	91.8

package Text::Hunspell::FFI;

use strict;
use warnings;
use 5.020;
use FFI::Platypus 1.00;
use FFI::CheckLib 0.27 ();
use experimental qw( postderef );

# ABSTRACT: Perl FFI interface to the Hunspell library
our $VERSION = '0.04'; # VERSION

sub _lib
{
  my @args = (lib => '*', verify => sub { $_[0] =~ /hunspell/ }, symbol => "Hunspell_create");
  my @libs = FFI::CheckLib::find_lib @args;
  my($first) = @libs
    ? @libs
    : FFI::CheckLib::find_lib @args, alien => 'Alien::Hunspell';
  die "unable to find libs" unless $first;
  $first;
}

my $ffi = FFI::Platypus->new(
  api => 1,
  lib => _lib(),
);

$ffi->attach(['Hunspell_create'=>'new'] => ['string','string'] => 'opaque', sub
{
  my($xsub, $class, $aff, $dic) = @_;
  my $ptr = $xsub->($aff, $dic);
  bless \$ptr, $class;
});


$ffi->attach(['Hunspell_destroy'=>'DESTROY'] => ['opaque'] => 'void', sub
{
  my($xsub, $self) = @_;
  $xsub->($$self);
});

foreach my $try (qw( Hunspell_add_dic _ZN8Hunspell7add_dicEPKcS1_ ))
{
  eval {
    $ffi->attach([$try=>'add_dic'] => ['opaque','string'] => 'void', sub
    {
      my($xsub, $self, $dpath) = @_;
      $xsub->($$self, $dpath);
    });
  };
  last unless $@;
}

unless(__PACKAGE__->can('add_dic'))
{
  # TODO: fallback on Perl implementation ?
  die "unable to find add_dic";
}

$ffi->attach(['Hunspell_spell'=>'check'] => ['opaque','string'] => 'int', sub
{
  my($xsub, $self, $word) = @_;
  $xsub->($$self, $word);
});

$ffi->attach(['Hunspell_free_list',=>'_free_list'] => ['opaque','opaque*','int'] => 'void');

sub _string_array_and_word
{
  my($xsub, $self, $word) = @_;
  my $ptr;
  my $count = $xsub->($$self, \$ptr, $word);
  my @result = defined $ptr ? map { $ffi->cast('opaque','string',$_) } $ffi->cast('opaque',"opaque[$count]", $ptr)->@* : ();
  _free_list($self, $ptr, $count) if defined $ptr;
  wantarray ? @result : $result[0];  ## no critic (Freenode::Wantarray)
}

$ffi->attach(['Hunspell_suggest'=>'suggest'] => ['opaque','opaque*','string'] => 'int', \&_string_array_and_word);
$ffi->attach(['Hunspell_analyze'=>'analyze'] => ['opaque','opaque*','string'] => 'int', \&_string_array_and_word);

$ffi->attach(['Hunspell_generate'=>'generate'] => ['opaque','opaque*','string','string'] => 'int', sub {
  my($xsub, $self, $word, $word2) = @_;
  my $ptr;
  my $count = $xsub->($$self, \$ptr, $word, $word2);
  my @result = defined $ptr ? map { $ffi->cast('opaque','string',$_) } $ffi->cast('opaque',"opaque[$count]", $ptr)->@* : ();
  _free_list($self, $ptr, $count) if $ptr;
  wantarray ? @result : $result[0];  ## no critic (Freenode::Wantarray)
});

$ffi->attach(['Hunspell_generate2'=>'generate2'] => ['opaque','opaque*','string','string[]','int'] => 'int', sub
{
  my($xsub, $self, $word, $suggestions) = @_;
  my $n = scalar @$suggestions;
  my $ptr;
  my $count = $xsub->($$self, \$ptr, $word, [@$suggestions], 1);
  my @result = defined $ptr ? map { $ffi->cast('opaque','string',$_) } $ffi->cast('opaque',"opaque[$count]", $ptr)->@* : ();
  _free_list($self, $ptr, $count) if defined $ptr;
  wantarray ? @result : $result[0];  ## no critic (Freenode::Wantarray)
});

1;

__END__