File Coverage

blib/lib/Text/Diff3/DiffHeckel.pm

Criterion	Covered	Total	%
statement	59	63	93.6
branch	12	14	85.7
condition	22	27	81.4
subroutine	7	7	100.0
pod	1	1	100.0
total	101	112	90.1

package Text::Diff3::DiffHeckel;
# two-way diff plug-in
use 5.006;
use strict;
use warnings;
use base qw(Text::Diff3::Base);

use version; our $VERSION = '0.08';

sub diff {
    my($self, $A, $B) = @_;
    my $f = $self->factory;
    if (! $self->_is_a_text($A)) {
        $A = $f->create_text($A);
    }
    if (! $self->_is_a_text($B)) {
        $B = $f->create_text($B);
    }
    my $diff = $f->create_list2;
    my @uniq = (
        [$A->first_index - 1, $B->first_index - 1],
        [$A->last_index  + 1, $B->last_index  + 1]
    );
    my(%freq, %ap, %bp);
    for my $lineno ($A->range) {
        my $s = $A->at($lineno);
        $freq{$s} += 2;
        $ap{$s} = $lineno;
    }
    for my $lineno ($B->range) {
        my $s = $B->at($lineno);
        $freq{$s} += 3;
        $bp{$s} = $lineno;
    }
    while (my($s, $x) = each %freq) {
        next if $x != 5;
        push @uniq, [$ap{$s}, $bp{$s}];
    }
    @uniq = sort { $a->[0] <=> $b->[0] } @uniq;
    my($AL, $BL) = ($A->last_index,  $B->last_index);
    my($a1, $b1) = ($A->first_index, $B->first_index);
    while ($a1 <= $AL && $b1 <= $BL && $A->eq_at($a1, $B->at($b1))) {
        $a1++;
        $b1++;
    }
    my($a0, $b0) = ($a1, $b1);
    for (@uniq) {
        my($auniq, $buniq) = @{$_};
        next if $auniq < $a0 || $buniq < $b0;
        ($a1, $b1) = ($auniq - 1, $buniq - 1);
        while ($a0 <= $a1 && $b0 <= $b1 && $A->eq_at($a1, $B->at($b1))) {
            $a1--;
            $b1--;
        }
        if ($a0 <= $a1 && $b0 <= $b1) {
            $diff->push($f->create_range2('c', $a0, $a1, $b0, $b1));
        } elsif ($a0 <= $a1) {
            $diff->push($f->create_range2('d', $a0, $a1, $b0, $b0 - 1));
        } elsif ($b0 <= $b1) {
            $diff->push($f->create_range2('a', $a0, $a0 - 1, $b0, $b1));
        }
        ($a1, $b1) = ($auniq + 1, $buniq + 1);
        while ($a1 <= $AL && $b1 <= $BL && $A->eq_at($a1, $B->at($b1))) {
            $a1++;
            $b1++;
        }
        ($a0, $b0) = ($a1, $b1);
    }
    return $diff;
}

sub _is_a_text {
    my($self, $x) = @_;
    return eval{ $x->can('first_index') }
        && eval{ $x->can('last_index') }
        && eval{ $x->can('range') }
        && eval{ $x->can('at') }
        && eval{ $x->can('eq_at') };
}

1;

__END__