File Coverage

blib/lib/Text/Diff3/Diff3.pm

Criterion	Covered	Total	%
statement	69	75	92.0
branch	22	26	84.6
condition	6	9	66.6
subroutine	7	7	100.0
pod	1	1	100.0
total	105	118	88.9

package Text::Diff3::Diff3;
# diff3 component
use 5.006;
use strict;
use warnings;

use base qw(Text::Diff3::Base);

use version; our $VERSION = '0.08';

# the three-way diff procedure based on the GNU diff3.c by Randy Smith.
sub diff3 {
    my($self, $text0, $text2, $text1) = @_;
    my $f = $self->factory;
    if (! $self->_is_a_text($text0)) {
        $text0 = $f->create_text($text0);
    }
    if (! $self->_is_a_text($text2)) {
        $text0 = $f->create_text($text2);
    }
    if (! $self->_is_a_text($text1)) {
        $text0 = $f->create_text($text1);
    }
    my $diffp = $f->create_diff;
    my @diff2 = (
        $diffp->diff($text2, $text0),
        $diffp->diff($text2, $text1),
    );
    my $diff3 = $f->create_list3;
    my $range3 = $f->create_null_range3;
    while (! $diff2[0]->is_empty || ! $diff2[1]->is_empty) {
        # find a continual range in text2 $lo2..$hi2
        # changed by text0 or by text1.
        #
        #  diff2[0]     222    222222222
        #     text2  ...L!!!!!!!!!!!!!!!!!!!!H...
        #  diff2[1]       222222   22  2222222
        my @range2 = ([], []);
        my $i =
              $diff2[0]->is_empty ? 1
            : $diff2[1]->is_empty ? 0
            : $diff2[0]->first->loA <= $diff2[1]->first->loA ? 0
            : 1;
        my $j = $i;
        my $k = $i ^ 1;
        my $hi = $diff2[$j]->first->hiA;
        push @{$range2[$j]}, $diff2[$j]->shift;
        while (! $diff2[$k]->is_empty && $diff2[$k]->first->loA <= $hi + 1) {
            my $hi_k = $diff2[$k]->first->hiA;
            push @{$range2[$k]}, $diff2[$k]->shift;
            if ($hi < $hi_k) {
                $hi = $hi_k;
                $j = $k;
                $k = $k ^ 1;
            }
        }
        my $lo2 = $range2[$i][ 0]->loA;
        my $hi2 = $range2[$j][-1]->hiA;
        # take the corresponding ranges in text0 $lo0..$hi0
        # and in text1 $lo1..$hi1.
        #
        #     text0  ..L!!!!!!!!!!!!!!!!!!!!!!!!!!!!H...
        #  diff2[0]     222    222222222
        #     text2  ...00!1111!000!!00!111111...
        #  diff2[1]       222222   22  2222222
        #     text1       ...L!!!!!!!!!!!!!!!!H...
        my($lo0, $hi0);
        if (@{$range2[0]}) {
            $lo0 = $range2[0][ 0]->loB - $range2[0][ 0]->loA + $lo2;
            $hi0 = $range2[0][-1]->hiB - $range2[0][-1]->hiA + $hi2;
        } else {
            $lo0 = $range3->hi0 - $range3->hi2 + $lo2;
            $hi0 = $range3->hi0 - $range3->hi2 + $hi2;
        }
        my($lo1, $hi1);
        if (@{$range2[1]}) {
            $lo1 = $range2[1][ 0]->loB - $range2[1][ 0]->loA + $lo2;
            $hi1 = $range2[1][-1]->hiB - $range2[1][-1]->hiA + $hi2;
        } else {
            $lo1 = $range3->hi1 - $range3->hi2 + $lo2;
            $hi1 = $range3->hi1 - $range3->hi2 + $hi2;
        }
        $range3 = $f->create_range3(
            undef, $lo0, $hi0, $lo1, $hi1, $lo2, $hi2
        );
        # detect type of changes.
        if (! @{$range2[0]}) {
            $range3->type('1');
        } elsif (! @{$range2[1]}) {
            $range3->type('0');
        } elsif ($hi0 - $lo0 != $hi1 - $lo1) {
            $range3->type('A');
        } else {
            $range3->type('2');
            for my $d (0 .. $hi0 - $lo0) {
                if (! $text0->eq_at($lo0 + $d, $text1->at($lo1 + $d))) {
                    $range3->type('A');
                    last;
                }
            }
        }
        $diff3->push($range3);
    }
    return $diff3;
}

sub _is_a_text {
    my($self, $x) = @_;
    return eval{ $x->can('at') } && eval{ $x->can('eq_at') };
}

1;

__END__