File Coverage

blib/lib/Text/BlockLayout.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	2	2	100.0
condition	7	9	77.7
subroutine	10	10	100.0
pod	1	3	33.3
total	63	67	94.0

package Text::BlockLayout;

use 5.010;
use strict;
use warnings;
use utf8;
use Text::Wrap ();

our $VERSION = '0.02';

use Moo;

has max_width => (
    is          => 'rw',
    required    => 1,
);

has line_continuation_threshold => (
    is          => 'rw',
    default     => sub { int(shift->max_width * 2 / 3 + 0.5) },
    lazy        => 1,
);
has separator => (
    is      => 'rw',
    default => sub { ' ' },
);

sub add_text {
    my ($self, @chunks) = @_;

    push @{$self->{chunks}}, map [0, $_], @chunks;
    $self;
}

sub add_line {
    my ($self, @chunks) = @_;

    push @{$self->{chunks}}, map [1, $_], @chunks;
    $self;
}

sub formatted {
    my $self = shift;

    my @lines;
    my $last_line_separate = 0;
    for my $chunk ( @{ $self->{chunks} }) {
        my ($separate_line, $text) = @$chunk;
        my $start_new_line   = $last_line_separate || $separate_line || !@lines;
           $start_new_line ||= length($lines[-1]) > $self->line_continuation_threshold;
           $start_new_line ||= (length($lines[-1]) + length($self->separator) + length $text) > $self->max_width;
        if ($start_new_line) {
            push @lines, $self->_wrap($text);
        }
        else {
            $lines[-1] .= $self->separator . $text;
        }
        $last_line_separate = $separate_line;
    }
    return join "\n", @lines, '';
}

sub _wrap {
    my ($self, $text) = @_;
    # it seems Text::Wrap includes the final newline, so +1
    local $Text::Wrap::columns = 1 + $self->max_width;
    return split /\n/, Text::Wrap::wrap('', '', $text);
}

1;

__END__