File Coverage

blib/lib/Test2/Require/Module.pm

Criterion	Covered	Total	%
statement	30	31	96.7
branch	9	10	90.0
condition			n/a
subroutine	7	7	100.0
pod	0	3	0.0
total	46	51	90.2

package Test2::Require::Module;
use strict;
use warnings;

use base 'Test2::Require';

our $VERSION = '0.000153';

use Test2::Util qw/pkg_to_file/;

sub skip {
    my $class = shift;
    my ($module, $ver) = @_;

    return "Module '$module' is not installed"
        unless check_installed($module);

    return undef unless defined $ver;

    return check_version($module, $ver);
}

sub check_installed {
    my ($mod) = @_;
    my $file = pkg_to_file($mod);

    return 1 if eval { require $file; 1 };
    my $error = $@;

    return 0 if $error =~ m/Can't locate \Q$file\E in \@INC/;

    # Some other error, rethrow it.
    die $error;
}

sub check_version {
    my ($mod, $ver) = @_;

    return undef if eval { $mod->VERSION($ver); 1 };
    my $have = $mod->VERSION;
    return "Need '$mod' version $ver, have $have.";
}

1;

__END__