File Coverage

blib/lib/Test2/Plugin/UTF8.pm

Criterion	Covered	Total	%
statement	27	31	87.1
branch	4	10	40.0
condition	1	2	50.0
subroutine	6	6	100.0
pod			n/a
total	38	49	77.5

package Test2::Plugin::UTF8;
use strict;
use warnings;

our $VERSION = '0.000153';

use Carp qw/croak/;

use Test2::API qw{
    test2_add_callback_post_load
    test2_stack
};

my $LOADED = 0;

sub import {
    my $class = shift;

    my $import_utf8 = 1;
    while ( my $arg = shift @_ ) {
        croak "Unsupported import argument '$arg'" unless $arg eq 'encoding_only';
        $import_utf8 = 0;
    }

    # Load and import UTF8 into the caller.
    if ( $import_utf8 ) {
        require utf8;
        utf8->import;
    }

    return if $LOADED++; # do not add multiple hooks

    # Set the output formatters to use utf8
    test2_add_callback_post_load(sub {
        my $stack = test2_stack;
        $stack->top; # Make sure we have at least 1 hub

        my $warned = 0;
        for my $hub ($stack->all) {
            my $format = $hub->format || next;

            unless ($format->can('encoding')) {
                warn "Could not apply UTF8 to unknown formatter ($format)\n" unless $warned++;
                next;
            }

            $format->encoding('utf8');
        }
    });
}

1;

__END__