File Coverage

blib/lib/Test2/Plugin/NoWarnings.pm

Criterion	Covered	Total	%
statement	19	19	100.0
branch	1	2	50.0
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	26	27	96.3

package Test2::Plugin::NoWarnings;

use strict;
use warnings;

our $VERSION = '0.09';

# This is the version that added test2_is_testing_done.
use Test2 1.302167;
use Test2::API qw( context_do test2_is_testing_done );
use Test2::Event::Warning;

my $echo = 0;

sub import {
    shift;
    my %args = @_;
    $echo = $args{echo} if exists $args{echo};
    return;
}

my $_orig_warn_handler = $SIG{__WARN__};
## no critic (Variables::RequireLocalizedPunctuationVars)
$SIG{__WARN__} = sub {
    unless ( test2_is_testing_done() ) {
        my $w = $_[0];
        $w =~ s/\n+$//g;

        context_do {
            my $ctx = shift;
            $ctx->send_event(
                'Warning',
                warning => "Unexpected warning: $w",
            );
        }
        $_[0];

        return unless $echo;
    }

    return if $_orig_warn_handler && $_orig_warn_handler eq 'IGNORE';

    # The rest was copied from Test::Warnings

    # TODO: this doesn't handle blessed coderefs... does anyone care?
    goto &$_orig_warn_handler
        if $_orig_warn_handler
        and (
        ( ref $_orig_warn_handler eq 'CODE' )
        or (    $_orig_warn_handler ne 'DEFAULT'
            and $_orig_warn_handler ne 'IGNORE'
            and defined &$_orig_warn_handler )
        );

    if ( $_[0] =~ /\n$/ ) {
        warn $_[0];
    }
    else {
        require Carp;
        Carp::carp( $_[0] );
    }
};

1;

# ABSTRACT: Fail if tests warn

__END__