File Coverage

blib/lib/Test2/Plugin/IOMuxer/Layer.pm

Criterion	Covered	Total	%
statement	39	46	84.7
branch	3	6	50.0
condition			n/a
subroutine	9	9	100.0
pod	0	2	0.0
total	51	63	80.9

package Test2::Plugin::IOMuxer::Layer;
use strict;
use warnings;

BEGIN {
    local $@ = undef;
    my $ok = eval {
        require JSON::MaybeXS;
        JSON::MaybeXS->import('JSON');
        1;
    };

    unless($ok) {
        require JSON::PP;
        *JSON = sub() { 'JSON::PP' };
    }

    my $json = JSON()->new->utf8(1);

    sub encode_json { $json->encode(@_) }
}

use Time::HiRes qw/time/;

our $VERSION = '0.000007';

use Test2::Plugin::OpenFixPerlIO;
use IO::Handle;

our %MUXED;
our %MUX_FILES;

sub PUSHED {
    my ($class, $mode, $handle) = @_;
    $handle->autoflush(1);
    bless {}, $class;
}

sub WRITE {
    my ($self, $buffer, $handle) = @_;

    if ($self->{DIED}) {
        print $handle $buffer;
        return length($buffer);
    }

    my $ok = eval {
        my $time = time;
        my $fileno = fileno($handle);

        my $json = encode_json({stamp => $time, fileno => $fileno, buffer => $buffer});
        my $mh = $MUX_FILES{$MUXED{$fileno}};
        print $mh $json, "\n";

        1;
    };
    my $err = $@;

    print $handle $buffer;

    unless ($ok) {
        $self->{DIED}++;
        die $err;
    }

    return length($buffer);
}

1;

__END__