File Coverage

blib/lib/Test2/Plugin/DBIProfile.pm

Criterion	Covered	Total	%
statement	40	41	97.5
branch	6	10	60.0
condition	1	2	50.0
subroutine	9	9	100.0
pod	0	1	0.0
total	56	63	88.8

package Test2::Plugin::DBIProfile;
use strict;
use warnings;

our $VERSION = '0.002006';

use DBI::Profile qw/dbi_profile_merge_nodes/;
use Test2::API qw/test2_add_callback_exit context/;
use Test2::Util::Times qw/render_duration/;

my $ADDED_HOOK = 0;

sub import {
    my $class = shift;
    my ($path) = @_;

    if (defined $path) {
        $ENV{DBI_PROFILE} = $path;
    }
    else {
        $ENV{DBI_PROFILE} //= "!MethodClass";
    }

    return if $ADDED_HOOK++;

    $DBI::Profile::ON_DESTROY_DUMP = undef;
    $DBI::Profile::ON_FLUSH_DUMP   = undef;

    my $ran = 0;
    my $callback = sub {
        return if $ran++;
        send_profile_event(@_);
    };

    test2_add_callback_exit($callback);

    # Fallback
    eval 'END { local $?; my $ctx = context(); $callback->($ctx); $ctx->release }; 1' or die $@;
}

sub send_profile_event {
    my ($ctx, $real, $new) = @_;

    my $p = $DBI::shared_profile or return;

    my $data = $p->{Data};
    my ($summary) = $p->format;

    my @totals;
    dbi_profile_merge_nodes(\@totals, $data);
    my ($count, $time) = @totals;

    $ctx->send_ev2(
        dbi_profile => $data,

        about => {package => __PACKAGE__, details => $summary},
        info  => [{tag => 'DBI-PROF', details => $summary}],

        harness_job_fields => [
            {name => "dbi_time",  details => render_duration($time), raw => $time},
            {name => "dbi_calls", details => $count},
        ],
    );
}

1;

__END__