File Coverage

blib/lib/Test2/Harness/Result.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	25	26	96.1
condition	18	27	66.6
subroutine	12	12	100.0
pod	6	7	85.7
total	115	126	91.2

package Test2::Harness::Result;
use strict;
use warnings;

our $VERSION = '0.000013';

use Carp qw/croak/;
use Time::HiRes qw/time/;

use Test2::Util::HashBase qw{
    file name job

    total      failed
    start_time stop_time
    exit

    plans

    events
};

sub init {
    my $self = shift;

    croak "'file' is a required attribute"
        unless $self->{+FILE};

    croak "'job' is a required attribute"
        unless $self->{+JOB};

    croak "'name' is a required attribute"
        unless $self->{+NAME};

    # Overall stuff
    $self->{+START_TIME} ||= time;
    $self->{+TOTAL}      ||= 0;
    $self->{+FAILED}     ||= 0;

    # Plan related
    $self->{+PLANS} ||= [];

    $self->{+EVENTS} ||= [];
}

sub stop {
    my $self = shift;
    my ($exit) = @_;

    $self->{+STOP_TIME} = time;
    $self->{+EXIT}      = $exit;
}

sub passed {
    my $self = shift;
    return unless defined $self->{+STOP_TIME};

    return 0 if $self->{+EXIT};
    return 0 if $self->{+FAILED};
    return 1;
}

sub ran_tests {
    my $self = shift;

    my $plans = $self->{+PLANS};
    return 0 if $plans && @$plans && $plans->[0]->directive eq 'SKIP';
    return 0 unless grep { $_->increments_count } @{$self->{+EVENTS}};
    return 1;
}

sub bump_failed { $_[0]->{+FAILED} += $_[1] || 1 }

sub add_events {
    my $self = shift;
    $self->add_event($_) for @_;
}

sub add_event {
    my $self = shift;
    my ($e) = @_;

    push @{$self->{+EVENTS}} => $e;

    return unless ($e->nested || 0) <= 0;

    $self->{+TOTAL}++ if $e->increments_count;
    if ($e->isa('Test2::Event::Plan')) {
        my @set = $e->sets_plan;
        push @{$self->{+PLANS}}, $e unless $set[1] && $set[1] eq 'NO PLAN';
    }

    $self->{+FAILED}++ if $e->causes_fail || $e->terminate;
}

1;

__END__