File Coverage

blib/lib/Test2/Harness/Parser.pm

Criterion	Covered	Total	%
statement	47	48	97.9
branch	14	16	87.5
condition	3	6	50.0
subroutine	10	10	100.0
pod	2	3	66.6
total	76	83	91.5

package Test2::Harness::Parser;
use strict;
use warnings;

our $VERSION = '0.000013';

use Carp qw/croak/;
use Scalar::Util qw/blessed/;

use Test2::Util qw/pkg_to_file/;

use Test2::Event::ParserSelect;

use Test2::Util::HashBase qw/proc job/;

sub morph {}

sub init {
    my $self = shift;

    croak "'proc' is a required attribute"
        unless $self->{+PROC};

    croak "'job' is a required attribute"
        unless $self->{+JOB};

    $self->morph;
}

sub step {
    my $self = shift;

    my $class = blessed($self);
    my $line = $self->proc->get_out_line(peek => 1);
    chomp $line if defined $line;
    return unless defined $line && length $line;

    if ($class eq __PACKAGE__ && $line) {
        if ($line =~ m/^T2_FORMATTER: (.+)$/) {
            chomp(my $fmt = $1);
            $fmt =~ s/[\r\s]+$//g;
            my $class = "Test2::Harness::Parser::$fmt";
            require(pkg_to_file($class));
            bless($self, $class);
            $self->morph;

            # Strip off the line, it has been processed
            $self->proc->get_out_line;

            return Test2::Event::ParserSelect->new(
                parser_class => $class,
            );
        }

        if ($line =~ m/^\s*(ok\b|not ok\b|1\.\.\d+|Bail out!|TAP version|^\#.+)/) {
            require Test2::Harness::Parser::TAP;
            bless($self, 'Test2::Harness::Parser::TAP');
            $self->morph;

            # Do not strip off the line, we need the TAP parser to eat it.
            return Test2::Event::ParserSelect->new(
                parser_class => 'Test2::Harness::Parser::TAP',
            );
        }
    }

    if ($class eq __PACKAGE__) {
        die 'You cannot use Test2::Harness::Parser itself, it must be subclassed';
    }
    else {
        die "The $class class must implement the step method";
    }
}

1;

__END__