File Coverage

blib/lib/Test/Stream/Exporter/Meta.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	18	18	100.0
condition	4	6	66.6
subroutine	12	12	100.0
pod	6	7	85.7
total	84	87	96.5

package Test::Stream::Exporter::Meta;
use strict;
use warnings;

my %EXPORT_META;

use Carp qw/croak confess/;

sub EXPORTS() { 'exports' }
sub PACKAGE() { 'package' }
sub DEFAULT() { 'default' }

sub exports { $_[0]->{+EXPORTS} }
sub default { $_[0]->{+DEFAULT} }
sub package { $_[0]->{+PACKAGE} }

sub get { $EXPORT_META{$_[-1]} }

sub new {
    my ($class, $pkg) = @_;

    confess "Package is required!"
        unless $pkg;

    my $meta = $EXPORT_META{$pkg};
    return $meta if $meta;

    $meta = bless({
        EXPORTS() => {},
        DEFAULT() => [],
        PACKAGE() => $pkg,
    }, $class);

    return $EXPORT_META{$pkg} = $meta;
}

sub add {
    my ($self, $default, $name, $ref) = @_;

    confess "Name is mandatory" unless $name;

    confess "$name is already exported"
        if $self->{+EXPORTS}->{$name};

    my $pkg = $self->{+PACKAGE};

    unless ($ref) {
        no strict 'refs';
        $ref = *{"$pkg\::$name"}{CODE};
    }

    confess "No reference or package sub found for '$name' in '$pkg'"
        unless $ref && ref $ref;

    # Add the export ref
    $self->{+EXPORTS}->{$name} = $ref;
    push @{$self->{+DEFAULT}} => $name if $default;
}

sub add_bulk {
    my $self    = shift;
    my $default = shift;

    my $pkg = $self->{+PACKAGE};

    for my $name (@_) {
        confess "$name is already exported"
            if $self->{+EXPORTS}->{$name};

        no strict 'refs';
        $self->{+EXPORTS}->{$name} = *{"$pkg\::$name"}{CODE}
            || confess "No reference or package sub found for '$name' in '$pkg'";
    }

    push @{$self->{+DEFAULT}} => @_ if $default;
}

1;

__END__