File Coverage

blib/lib/Test/SkipWithout.pm

Criterion	Covered	Total	%
statement	23	26	88.4
branch	7	10	70.0
condition			n/a
subroutine	4	4	100.0
pod	0	1	0.0
total	34	41	82.9

package Test::SkipWithout;
use strict;
use warnings;

our $VERSION = "0.001_001";

sub import {
    my $class = shift;
    my ($module, $version) = @_;

    my ($pkg, $file, $line) = caller;

    my $ok = eval qq{require $module; 1};
    my $err = $@;

    unless ($ok) {
        # This will probably break in perl5i since it changes the message, oh well.
        return skip("$module is not installed, skipping test.")
            if $err =~ m/Can't locate .* in \@INC/;

        die "Error loading module '$module' at $file line $line.\n$err";
    }

    return unless $version;

    $ok = eval {$module->VERSION($version)};
    $err = $@;

    unless ($ok) {
        if ($err =~ m/^($module version \S+ required--this is only version \S+) at/) {
            return skip($1);
        }

        die "Error checking version for module '$module' at $file line $line.\n$err";
    }
}

sub skip {
    my ($reason) = @_;

    require Test::More;
    Test::More::plan('skip_all' => $reason);

    exit 0;
}

1;

__END__