File Coverage

blib/lib/Test/More/Hooks.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	6	6	100.0
condition			n/a
subroutine	11	11	100.0
pod	2	4	50.0
total	52	54	96.3

package Test::More::Hooks;
use 5.008005;
use strict;
use warnings;

our $VERSION = "0.12";
use Carp qw(croak);
use Test::Builder::Module;
our @ISA    = qw(Test::Builder::Module);
our @EXPORT = qw(subtest before after);

# $ LEVEL is controlled by the local variable.
our $LEVEL  = 0;
my $BEFORE = {};
my $AFTER  = {};

BEGIN {
    croak "Test::More::Hooks must be loaded after Test::More."
        unless exists $INC{'Test/More.pm'};
}

sub subtest {
    my ($name, $subtests) = @_;
    $BEFORE->{$LEVEL}->() if 'CODE' eq ref $BEFORE->{$LEVEL};

    my $result;
    {
        local $LEVEL = $LEVEL + 1;
        my $tb = Test::More::Hooks->builder;
        $result = $tb->subtest(@_);
        _clean_hooks();
    };

    $AFTER->{$LEVEL}->() if 'CODE' eq ref $AFTER->{$LEVEL};
    return $result;
}

sub before (&) {
    my $block = shift;
    $BEFORE->{$LEVEL} = $block;
}

sub after (&) {
    my $block = shift;
    $AFTER->{$LEVEL} = $block;
}

sub level {
    return $LEVEL;
}

sub _clean_hooks {
    $BEFORE->{$LEVEL} = undef;
    $AFTER->{$LEVEL}  = undef;
}

1;
__END__