File Coverage

blib/lib/Test/MethodName.pm

Criterion	Covered	Total	%
statement	42	47	89.3
branch	4	10	40.0
condition			n/a
subroutine	10	11	90.9
pod	2	2	100.0
total	58	70	82.8

package Test::MethodName;
use strict;
use warnings;
use Test::More qw//;
use Module::Pluggable::Object;
use List::MoreUtils qw/any/;
use Module::Functions qw//;

our $VERSION = '0.01';

use Exporter;
our @ISA    = qw/Exporter/;
our @EXPORT = qw/method_ok all_methods_ok/;

sub method_ok {
    my ($module, $test_code) = @_;

    eval "require $module"; ## no critic
    if (my $e = $@) {
        Test::More::fail("fail to require $module: $e");
        return;
    }

    Test::More::note("test methods in $module");

    for my $function ( Module::Functions::get_full_functions($module) ) {
        Test::More::ok( $test_code->($function), "function: $function" );
    }
}

sub all_methods_ok {
    my ($search_path, $test_code, %param) = @_;

    # this code was borrowed from Test::LoadAllModules
    unless ($search_path) {
        Test::More::plan skip_all => 'no search path';
        exit;
    }
    Test::More::plan('no_plan');
    my @exceptions = @{ $param{except} || [] };
    my @lib = @{ $param{lib} || [ 'lib' ] };
    foreach my $module (
        grep { !_is_excluded( $_, @exceptions ) }
        sort do {
            local @INC = @lib;
            my $finder = Module::Pluggable::Object->new(
                search_path => $search_path );
            ( $search_path, $finder->plugins );
        }
        )
    {
        method_ok($module, $test_code);
    }
}

sub _is_excluded {
    my ( $module, @exceptions ) = @_;
    any { $module eq $_ || $module =~ /$_/ } @exceptions;
}

1;

__END__