File Coverage

lib/Test/Docker/Image.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	7	8	87.5
condition	3	4	75.0
subroutine	9	10	90.0
pod	3	3	100.0
total	59	64	92.1

package Test::Docker::Image;

use strict;
use warnings;

use Time::HiRes 'sleep';
use Data::Util ':check';
use Class::Load qw/try_load_class/;

use Class::Accessor::Lite (
    ro => [qw/tag container_ports container_id/],
);

our $VERSION = "0.04";

sub new {
    my $class = shift;
    my %args = @_ == 1 ? %{$_[0]} : @_;

    my $boot_class = delete $args{boot} || 'Test::Docker::Image::Boot';

    try_load_class( $boot_class ) or die "failed to load $boot_class";

    my $image_tag = delete $args{tag};
    die "tag argument is required" unless $image_tag;

    die "container_ports argument must be ArrayRef"
        unless is_array_ref $args{container_ports};

    my @ports = map { ('-p', $_) } @{ $args{container_ports} };

    my $boot         = $boot_class->new;
    my $container_id = $boot->docker_run(\@ports, $image_tag);

    # wait to launch the container
    sleep $args{sleep_sec} || 0.5;

    my $self = bless {
        tag             => $image_tag,
        container_ports => $args{container_ports},
        container_id    => $container_id,
        boot            => $boot,
        boot_class      => $boot_class,
    }, $class;

    return $self;
}

sub port {
    my ($self, $container_port) = @_;
    return $self->{boot}->docker_port($self->container_id, $container_port);
}

sub host {
    $_[0]->{boot}->host;
}

sub DESTROY {
    my $self = shift;
    $self->{boot}->on_destroy( $self->container_id );
}

1;
__END__