File Coverage

blib/lib/Test/Class/Filter/Tags.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	4	4	100.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	47	47	100.0

package Test::Class::Filter::Tags;

use strict;
use warnings;

use Attribute::Method::Tags;
use Attribute::Method::Tags::Registry;
use MRO::Compat;
use Test::Class;

use base qw( Exporter );

our $VERSION = '0.11';

# import the 'Tags' attribute into the caller
our @EXPORT = qw( Tags );

my $filter = sub {
    my ( $test_class, $test_method ) = @_;

    # don't filter if our relevant env vars not set`
    return 1 unless defined $ENV{ TEST_TAGS }
      or defined $ENV{ TEST_TAGS_SKIP };

    my $suppressed = grep {
        Attribute::Method::Tags::Registry->method_has_tag(
            $test_class,
            $test_method,
            $_
        )
    } __expand_filter_vars( $ENV{ TEST_TAGS_SKIP } );

    return 0 if $suppressed;

    # don't filter on set tags, if there are no set tags
    return 1 unless defined $ENV{ TEST_TAGS };

    my $matched = grep {
        Attribute::Method::Tags::Registry->method_has_tag(
            $test_class,
            $test_method,
            $_
        );
    } __expand_filter_vars( $ENV{ TEST_TAGS } );

    return 1 if $matched;
};

# as test_class permits changing of the TEST_METHOD definitions,
# support doing similar for our controlling ENV vars
sub __expand_filter_vars {
    my $val = shift;

    return if not defined $val;

    $val =~ s/^\s+//;
    $val =~ s/\s+$//;

    my @tags = split /[\s,]/, $val;

    return @tags;
}

# and finally, add our filter callback.
Test::Class->add_filter( $filter );

# supporting method, to determine if any instances of method have tag defined
# in current class, and all subclasses.
sub method_has_tag {
    my ( $self, $class, $method, $tag ) = @_;

    my $isa = mro::get_linear_isa( $class );
    foreach my $c ( @{ $isa } ) {
        return 1 if Attribute::Method::Tags::Registry->method_has_tag(
            $c, $method, $tag
        );
    }

    return 0;
}

1;

__END__