File Coverage

blib/lib/Teng/Plugin/SearchJoined/Iterator.pm

Criterion	Covered	Total	%
statement	12	41	29.2
branch	0	8	0.0
condition	0	3	0.0
subroutine	4	6	66.6
pod	1	1	100.0
total	17	59	28.8

package Teng::Plugin::SearchJoined::Iterator;
use strict;
use warnings;
use Carp ();
use Class::Accessor::Lite (
    new => 1,
    ro  => [qw/teng sql table_names fields/],
    rw  => [qw/sth suppress_object_creation/],
);

sub next {
    my $self = shift;

    my $wantarray = wantarray;
    if (defined $wantarray && $wantarray == 0) {
        Carp::carp('calling `next` method in scalar context is deprecated and forbidden in future');
    }

    my $row;
    if ($self->{sth}) {
        $row = $self->{sth}->fetchrow_arrayref;
        unless ( $row ) {
            $self->{sth}->finish;
            $self->{sth} = undef;
            return;
        }
    } else {
        return;
    }

    my $data = $self->_seperate_rows($row);

    if ($self->{suppress_object_creation}) {
        return @$data{ @{$self->{table_names}} };
    } else {
        return map { $self->{teng}->new_row_from_hash($_, $data->{$_}, $self->{sql}) } @{$self->{table_names}};
    }
}

sub _seperate_rows {
    my ($self, $row) = @_;
    my %data;
    my $name_sep = quotemeta $self->{teng}{sql_builder}{name_sep};
    my $i = 0;
    for my $field (@{ $self->{fields} }) {
        my $value = $row->[$i++];
        my ($table, $column) = split /$name_sep/, $field;
        $data{$table}{$column} = $value;
    }
    \%data;
}

1;
__END__