File Coverage

blib/lib/TAP/Harness/Restricted.pm

Criterion	Covered	Total	%
statement	32	32	100.0
branch	7	8	87.5
condition	1	2	50.0
subroutine	7	7	100.0
pod	1	1	100.0
total	48	50	96.0

use 5.008001;
use strict;
use warnings;

package TAP::Harness::Restricted;
# ABSTRACT: Skip some test files

our $VERSION = '0.004';

use superclass 'TAP::Harness' => 3.18;
use Path::Tiny;

sub aggregate_tests {
    my ( $self, $aggregate, @tests ) = @_;
    my %banned_files = map { $_ => undef } map { glob } split " ",
      $ENV{HARNESS_SKIP} || '';
    @tests = grep { _file_ok( $_, \%banned_files ) } @tests;
    return $self->SUPER::aggregate_tests( $aggregate, @tests );
}

my $maybe_prefix = qr/(?:\d+[_-]?)?/;

my @banned_names = (
    qr/${maybe_prefix}pod\.t/,
    qr/${maybe_prefix}pod[_-]?coverage\.t/,
    qr/${maybe_prefix}pod[_-]?spell(?:ing)?\.t/,
    qr/${maybe_prefix}perl[_-]?critic\.t/,
    qr/${maybe_prefix}kwalitee\.t/,
);

my @banned_code = (
    qr/\b (?: use | require )\ Test::(?:
        CleanNamespaces | DependentModules | EOL | Kwalitee | Mojibake
        | NoTabs | Perl::Critic | Pod | Portability::Files | Spelling | Vars
    )\b/x,
);

sub _file_ok {
    my $file         = path(shift);
    my $banned_files = shift;
    return unless $file->exists;
    my $basename = $file->basename;
    return if grep { $basename =~ $_ } @banned_names;
    return if exists $banned_files->{ $file->relative };
    my $guts = $file->slurp;
    return if grep { $guts =~ m{$_}ms } @banned_code;
    return 1;
}

1;


# vim: ts=4 sts=4 sw=4 et:

__END__