File Coverage

blib/lib/System/Info/BSD.pm

Criterion	Covered	Total	%
statement	9	26	34.6
branch	0	12	0.0
condition			n/a
subroutine	3	5	60.0
pod	1	1	100.0
total	13	44	29.5

package System::Info::BSD;

use strict;
use warnings;

use base "System::Info::Base";

our $VERSION = "0.051";

=head1 NAME

System::Info::BSD - Object for specific BSD info.

=head1 DESCRIPTION

=head2 $si->prepare_sysinfo()

Use os-specific tools to find out more about the system.

=cut

sub prepare_sysinfo {
    my $self = shift;
    $self->SUPER::prepare_sysinfo;

    my $sysctl = __get_sysctl ();
    $self->{__sysctl} = $sysctl;

    my $cpu = $sysctl->{model};

    if (exists $sysctl->{cpuspeed}) {
	$cpu .= sprintf " (%.0f MHz)", $sysctl->{cpuspeed};
	}
    elsif (exists $sysctl->{cpufrequency}) {
	$cpu .= sprintf " (%.0f MHz)", $sysctl->{cpufrequency}/1_000_000;
	}

    $self->{__cpu_type}  = $sysctl->{machine} if $sysctl->{machine};
    $self->{__cpu}       = $cpu               if $cpu;
    $self->{__cpu_count} = $sysctl->{ncpu};

    return $self;
    } # prepare_sysinfo

sub __get_sysctl {
    my $sysctl_cmd = -x "/sbin/sysctl" ? "/sbin/sysctl" : "sysctl";

    chomp (my @sysctl = `$sysctl_cmd -a hw`);
    my %sysctl = map m/^hw\.([\w.]+)\s*[:=]\s*(.*)$/ => @sysctl;
    $sysctl{machine} and $sysctl{machine} =~ s/Power Macintosh/macppc/;

    return \%sysctl;
    } # __get_sysctl

1;

__END__