File Coverage

blib/lib/Sub/Talisman/Struct.pm

Criterion	Covered	Total	%
statement	51	51	100.0
branch	6	6	100.0
condition	4	5	80.0
subroutine	12	12	100.0
pod	1	1	100.0
total	74	75	98.6

package Sub::Talisman::Struct;

use 5.012;
use strict;
use warnings;

BEGIN {
	$Sub::Talisman::Struct::AUTHORITY = 'cpan:TOBYINK';
	$Sub::Talisman::Struct::VERSION   = '0.005';
}

use base qw( Sub::Talisman );
use MooX::Struct ();
use Carp qw( confess );
use Data::OptList ();
use namespace::clean;

sub import
{
	my $class  = shift;
	my $caller = caller;

	foreach my $arg (@{ Data::OptList::mkopt(\@_) })
	{
		my ($atr, $str) = @$arg;
		$class->setup_for($caller => {
			attribute => $atr,
			struct    => $str,
		});
	}
}

my %PROCESSORS;
my %STRUCTS;
sub setup_for
{
	my ($class, $caller, $opts) = @_;
	$class->SUPER::setup_for($caller, $opts);
	my $proc   = $PROCESSORS{$caller} //= 'MooX::Struct::Processor'->new;
	my $struct = $proc->make_sub(
		$opts->{attribute},
		$opts->{struct} || [],
	);
	$STRUCTS{"$caller\::$opts->{attribute}"} = $struct;
}

sub _process_params
{
	my ($class, $attr, $params) = @_;

	my %new;
	my @p = @{ $params || [] };
	my @f = $STRUCTS{$attr}->()->FIELDS;
	confess "Too many parameters for attribute $attr" if @p > @f;
	for my $i ( 0 .. $#p )
	{
		$new{ $f[$i] } = $p[$i];
	}
	my $obj = eval { $STRUCTS{$attr}->()->new(%new) };
	return $obj if $obj;
	chomp(my $msg = $@);
	$msg =~ s{ at \(.+?\) line \d+\.?}{};
	confess $msg;
}

1;

__END__