File Coverage

blib/lib/Sub/Args.pm

Criterion	Covered	Total	%
statement	49	49	100.0
branch	24	26	92.3
condition	10	12	83.3
subroutine	7	7	100.0
pod	2	2	100.0
total	92	96	95.8

package Sub::Args;
use strict;
use warnings;
use 5.008001;
use Exporter 'import';
our @EXPORT = qw( args args_pos );
use Carp ();

our $VERSION = '0.08';

sub args {
    my $rule = shift;

    if (ref $rule ne 'HASH') {
        Carp::croak "args method require hashref's rule.";
    }

    my $invocant = caller(0);

    my $caller_args = ref($_[0]) eq 'HASH' ? $_[0] : {@_};
    unless (keys %$caller_args) {
        package DB;
        () = caller(1);

        shift @DB::args if $invocant eq (ref($DB::args[0])||$DB::args[0]);

        if (ref($DB::args[0]) eq 'HASH') {
            $caller_args = $DB::args[0];
        } else {
            if (scalar(@DB::args) % 2 == 1 ) {
                Carp::confess "arguments not allow excluding hash or hashref";
            }
            $caller_args = {@DB::args};
        }
    }

    map {($rule->{$_} && not defined $caller_args->{$_}) ? Carp::confess "Mandatory parameter '$_' missing.": () } keys %$rule;

    map {(not defined $rule->{$_}) ? Carp::confess "not listed in the following parameter: $_.": () } keys %$caller_args;

    map {$caller_args->{$_} = undef unless exists $caller_args->{$_}} keys %$rule;

    Internals::SvREADONLY %$caller_args, 1;
    $caller_args;
}

sub args_pos {
    my $invocant = caller(0);
    {
        package DB;
        () = caller(1);
        shift @DB::args if $invocant eq (ref($DB::args[0])||$DB::args[0]);
    }
    my @args = @DB::args;

    my @expected;
    for(my $i = 0; $i < @_; $i++){
        if ($_[$i] && not defined $args[0]) {
           Carp::confess "missing mandatory parameter. pos: $i";
        }
        $expected[$i] = shift @args;
    }
    if (scalar(@args) > 0) {
        Carp::confess 'too much arguments. This function requires only ' . scalar(@_) . ' arguments.';
    }

    wantarray ? @expected : \@expected;
}

1;
__END__