File Coverage

blib/lib/String/Elide/FromArray.pm

Criterion	Covered	Total	%
statement	38	39	97.4
branch	11	14	78.5
condition	12	14	85.7
subroutine	6	6	100.0
pod	1	1	100.0
total	68	74	91.8

package String::Elide::FromArray;

our $DATE = '2017-07-28'; # DATE
our $VERSION = '0.001'; # VERSION

use 5.010001;
use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(elide);

sub _elide_str {
    my ($str, $len, $opts) = @_;
    $opts //= {};
    $opts->{marker} //= '..';

    return $str if length($str) <= $len;
    my $l = $len - length($opts->{marker});
    $str = ($l > 0 ? substr($str, 0, $l) : '') . $opts->{marker};
    return $str if length($str) <= $len;
    substr($str, 0, $len);
}

sub elide {
    my ($ary, $len, $opts) = @_;
    $opts //= {};
    $opts->{marker}      //= '..';
    $opts->{list_marker} //= '..';
    $opts->{item_marker} //= '..';
    $opts->{sep}         //= ', ';

    my @ary;
    if ($opts->{max_item_len}) {
        @ary = map { _elide_str($_, $opts->{max_item_len},
                                {marker=>$opts->{item_marker}}) } @$ary;
    } else {
        @ary = @$ary;
    }

    my $str;
    if ($opts->{max_items}) {
        if (@ary > $opts->{max_items}) {
            splice @ary, $opts->{max_items};
            push @ary, $opts->{list_marker};
        }
    }
    $str = join($opts->{sep}, @ary);

    if (length($str) <= $len) {
        return $str;
    } else {
        return _elide_str($str, $len, {marker=>$opts->{marker}});
    }
}

1;
# ABSTRACT: Truncate string containing list of items

__END__