File Coverage

blib/lib/Starch/Store/DBIx/Connector.pm

Criterion	Covered	Total	%
statement	26	26	100.0
branch	1	2	50.0
condition			n/a
subroutine	9	9	100.0
pod	1	2	50.0
total	37	39	94.8

package Starch::Store::DBIx::Connector;
$Starch::Store::DBIx::Connector::VERSION = '0.02';
=head1 NAME

Starch::Store::DBIx::Connector - Starch storage backend using DBIx::Connector.

=head1 SYNOPSIS

    my $starch = Starch->new(
        store => {
            class => '::DBIx::Connector',
            connector => [
                $dsn,
                $username,
                $password,
                { RaiseError=>1, AutoCommit=>1 },
            ],
            table => 'my_states',
        },
    );

=head1 DESCRIPTION

This L store uses L to set and get state data.

Very little is documented in this module as it is just a subclass
of L modified to use L
instead of L.

=cut

use DBIx::Connector;
use Types::Standard -types;
use Scalar::Util qw( blessed );

use Moo;
use strictures 2;
use namespace::clean;

extends 'Starch::Store::DBI';

sub BUILD {
  my ($self) = @_;

  # Get this loaded as early as possible.
  $self->connector();

  return;
}

=head1 REQUIRED ARGUMENTS

=head2 connector

This must be set to either an array ref arguments for L
or a pre-built object (often retrieved using a method proxy).

When configuring Starch from static configuration files using a
L
is a good way to link your existing L object
constructor in with Starch so that starch doesn't build its own.

=cut


has '+_dbh_arg' => (
    isa      => (InstanceOf[ 'DBIx::Connector' ]) | ArrayRef,
    init_arg => 'connector',
    reader   => '_connector_arg',
);

has '+dbh' => (
    isa      => InstanceOf[ 'DBIx::Connector' ],
    init_arg => undef,
    reader   => 'connector',
    builder  => '_build_connector',
);
sub _build_connector {
    my ($self) = @_;

    my $connector = $self->_connector_arg();
    return $connector if blessed $connector;

    return DBIx::Connector->new( @$connector );
}

=head1 OPTIONAL ARGUMENTS

=head2 method

The L method to call when executing queries.
Must be one of C, C, or C.  Defaults to C.

=cut

has method => (
    is      => 'ro',
    isa     => Enum['run', 'txn', 'svp'],
    default => 'run',
);

=head2 mode

The L to use
when running the L.  Defaults to C which lets
L use whichever mode it has been configured to use.
Must be on of C, C, C, or C.

Typically you will not want to set this as you will have provided
a pre-built L object, using a method proxy, which
you've already called L on.

=cut

has mode => (
    is => 'ro',
    isa => (Enum['ping', 'fixup', 'no_ping']) | Undef,
);

=head1 METHODS

=head2 set

Set L.

=head2 get

Set L.

=head2 remove

Set L.

=cut

# Little clean hack to make all of the DBI code "just work".
# local() can be awesome.
our $dbh;
sub dbh { $dbh }

around qw( set get remove ) => sub{
    my ($orig, $self, @args) = @_;

    local $Carp::Interal{ (__PACKAGE__) } = 1;

    my $method = $self->method();
    my $mode = $self->mode();

    return $self->connector->$method(
        defined($mode) ? ($mode) : (),
        sub{
            local $dbh = $_;
            return $self->$orig( @args );
        },
    );
};

1;
__END__