File Coverage

lib/Spreadsheet/Engine/Fn/Approximator.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	4	4	100.0
condition	8	11	72.7
subroutine	4	4	100.0
pod	1	1	100.0
total	47	50	94.0

package Spreadsheet::Engine::Fn::Approximator;

use strict;
use warnings;

use base 'Exporter';

our @EXPORT_OK = qw/iterate/;

sub iterate {
  my %arg = @_;

  my $guess   = $arg{initial_guess}  || 0.01;
  my $maxloop = $arg{max_iterations} || 20;
  my $epsilon = $arg{epsilon}        || 0.0000001;

  my $value    = $guess;
  my $oldvalue = 0;
  my $delta    = 1;
  my $olddelta;
  my $factor;
  my $tries = 0;

  while (abs($delta) > $epsilon && ($value != $oldvalue)) {
    $delta = $arg{function}->($value);

    if (defined $olddelta) {
      my $m = ($delta - $olddelta) / ($value - $oldvalue);    # get slope
      $oldvalue = $value;
      $value    = $value - $delta / ($m || 0.01);    # look for zero crossing
      $olddelta = $delta;
    } else {    # first time - no old values
      $oldvalue = $value;
      $value    = 1.1 * $value;
      $olddelta = $delta;
    }

    # error if we don't converge quickly enough
    return if (++$tries >= $maxloop);
  }

  return $value;
}

1;

__END__