File Coverage

blib/lib/SmokeRunner/Multi/Config.pm

Criterion	Covered	Total	%
statement	27	27	100.0
branch	4	4	100.0
condition	2	3	66.6
subroutine	10	10	100.0
pod			n/a
total	43	44	97.7

package SmokeRunner::Multi::Config;
our $AUTHORITY = 'cpan:YANICK';
#ABSTRACT: Config information for a Smokerunner::Multi setup
$SmokeRunner::Multi::Config::VERSION = '0.21';
use strict;
use warnings;

use Moo;
with 'MooX::Singleton';

use File::Spec;
use File::HomeDir;
use YAML::Syck qw( LoadFile );

has config => (
    is => 'ro',
    default => sub {
        my $self = shift;

        my $file = $self->_FindConfigFile;

        my $cfg = LoadFile($file);

        die "Config in $file for the smoke-runner was not valid.\n"
            unless $cfg && $cfg->{root};

        return $cfg;
    },
);

sub _FindConfigFile
{
    my $class = shift;

    my @files = (
        $class->_config_from_env,
        $class->_config_from_home,
        $class->_config_from_system,
    );

    for my $file (@files)
    {
        return $file if -f $file && -r _;
    }

    die "Cannot find a config file for the smoke-runner. Looked in [@files].\n";
}

sub _config_from_env {
    return $ENV{SMOKERUNNER_CONFIG} if $ENV{SMOKERUNNER_CONFIG};

    return;
}

sub _config_from_home {
    return File::Spec->catfile( File::HomeDir->my_home , '.smokerunner',
        'smokerunner.conf' );
}

sub _config_from_system { return '/etc/smokerunner/smokerunner.conf' }

has root_dir => (
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->config->{root} },
);

has runner => (
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->config->{runner} },
);

has smolder => (
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->config->{smolder} || {} },
);

has reporter => (
    is => 'ro',
    lazy => 1,
    default => sub { $_[0]->config->{reporter} },
);

1;

__END__