File Coverage

blib/lib/SmokeRunner/Multi/Validate.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	2	4	50.0
condition			n/a
subroutine	15	15	100.0
pod			n/a
total	76	78	97.4

package SmokeRunner::Multi::Validate;
our $AUTHORITY = 'cpan:YANICK';
#ABSTRACT: Wrapper around Params::Validate for SmokeRunner::Multi
$SmokeRunner::Multi::Validate::VERSION = '0.20';
use strict;
use warnings;

use base 'Exporter';

use Params::Validate qw(:types);
use Scalar::Util qw( blessed );


my %Types;
BEGIN
{
    %Types =
        (
        DIR_TYPE => { type      => SCALAR,
                      callbacks => { 'is a dir' => sub { -d $_[0] } },
                    },

        TEST_SET_TYPE => { type => OBJECT,
                           isa  => 'SmokeRunner::Multi::TestSet',
                         },

        RUNNER_TYPE => { type => OBJECT,
                         isa  => 'SmokeRunner::Multi::Runner',
                       },
    );

    for my $t ( grep {/^[A-Z]+$/} @Params::Validate::EXPORT_OK )
    {
        my $name = $t . '_TYPE';
        $Types{$name} = { type => eval $t };
    }

    for my $t ( keys %Types )
    {
        my %t   = %{ $Types{$t} };

        my $sub = sub { die "Invalid additional args for $t: [@_]" if @_ % 2;
                        return { %t, @_ };
                    };

        no strict 'refs';
        *{$t} = $sub;
    }
}

our %EXPORT_TAGS = ( types => [ keys %Types ] );
our @EXPORT_OK = keys %Types;

my %MyExports = map { $_ => 1 }
    @EXPORT_OK,
    map { ":$_" } keys %EXPORT_TAGS;

sub import
{
    my $class = shift;

    my $caller = caller;

    my @pv_export = grep { !$MyExports{$_} } @_;

    {
        eval <<"EOF";
package $caller;

use Params::Validate qw(@pv_export);
EOF

        die $@ if $@;
    }

    $class->export_to_level( 1, undef, grep { $MyExports{$_} } @_ );
}


1;

__END__