File Coverage

blib/lib/SmokeRunner/Multi/TestSet/SVN.pm

Criterion	Covered	Total	%
statement	37	44	84.0
branch	6	10	60.0
condition			n/a
subroutine	10	12	83.3
pod	1	1	100.0
total	54	67	80.6

package SmokeRunner::Multi::TestSet::SVN;
our $AUTHORITY = 'cpan:YANICK';
#ABSTRACT: Represents a set of test based on an SVN checkout
$SmokeRunner::Multi::TestSet::SVN::VERSION = '0.20';
use strict;
use warnings;

use base 'SmokeRunner::Multi::TestSet';

use DateTime::Format::Strptime;
use File::Spec;
use File::Which;
use SmokeRunner::Multi::SafeRun qw( safe_run );


sub _new
{
    my $class = shift;
    my %p     = @_;

    return unless -d File::Spec->catdir( $p{set_dir}, '.svn' );

    return bless \%p, $class;
}

sub _last_mod_time
{
    my $self = shift;

    my $uri = $self->_svn_uri();

    my $output = $self->_run_svn( 'info', $uri );

    die "Cannot get last_mod_time for SVN set in " . $self->set_dir()
        unless $output =~ /^Last Changed Date: (\S+) (\S+) (\S+)/m;

    my ( $date, $time, $tz ) = ( $1, $2, $3 );

    my $parser =
        DateTime::Format::Strptime->new
            ( pattern   => '%F %T',
              time_zone => $tz,
            );

    return $parser->parse_datetime("$date $time")->epoch;
}

sub _svn_uri
{
    my $self = shift;

    return $self->{svn_uri} if $self->{svn_uri};

    my $output = $self->_run_svn( 'info', $self->set_dir() );

    die "Cannot determine svn URI\n"
        unless $output =~ /^URL: (\S+)/m;

    return $self->{svn_uri} = $1;
}

sub update_files
{
    my $self = shift;

    $self->_run_svn(  'up', $self->set_dir() );
}

sub _run_svn
{
    my $self = shift;

    my $stdout;
    my $stderr;
    safe_run( command       => 'svn',
              args          => [@_],
              stdout_buffer => \$stdout,
              stderr_buffer => \$stderr,
            );

    die "Error running svn:\n$stderr\n"
        if $stderr;

    return $stdout;
}


1;

__END__