File Coverage

lib/Sisimai/Mail/Memory.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch	6	6	100.0
condition	5	6	83.3
subroutine	6	6	100.0
pod	2	2	100.0
total	49	50	98.0

package Sisimai::Mail::Memory;
use feature ':5.10';
use strict;
use warnings;
use Class::Accessor::Lite (
    'new' => 0,
    'ro'  => [
        'path',     # [String] Fixed string ""
        'size',     # [Integer] data size
    ],
    'rw'  => [
        'payload',  # [Array] entire bounce mail message
        'offset',   # [Integer] Index of "data"
    ]
);

sub new {
    # Constructor of Sisimai::Mail::Memory
    # @param    [String] argv1          Entire email string
    # @return   [Sisimai::Mail::Memory] Object
    #           [Undef]                 is not a valid email text
    my $class = shift;
    my $argv1 = shift // return undef;
    my $param = {
        'payload' => [],
        'path'    => '',
        'size'    => length $$argv1 || 0,
        'offset'  => 0,
    };
    return undef unless $param->{'size'};

    if( (substr($$argv1, 0, 5) || '') eq 'From ') {
        # UNIX mbox
        $param->{'payload'} = [split(/^From /m, $$argv1)];
        shift @{ $param->{'payload'} };
        $_ = 'From '.$_ for @{ $param->{'payload'} };
    } else {
        $param->{'payload'} = [$$argv1];
    }
    return bless($param, __PACKAGE__);
}

sub read {
    # Memory reader, works as a iterator.
    # @return   [String] Contents of a bounce mail
    my $self = shift;
    return undef unless scalar @{ $self->{'payload'} };

    $self->{'offset'} += 1;
    return shift @{ $self->{'payload'} };
}

1;
__END__