File Coverage

blib/lib/Shell/Command.pm

Criterion	Covered	Total	%
statement	27	28	96.4
branch	6	8	75.0
condition	3	5	60.0
subroutine	9	9	100.0
pod			n/a
total	45	50	90.0

package Shell::Command;
BEGIN {
  $Shell::Command::AUTHORITY = 'cpan:FLORA';
}
BEGIN {
  $Shell::Command::VERSION = '0.06';
}
# ABSTRACT: Cross-platform functions emulating common shell commands

# This must come first before ExtUtils::Command is loaded to ensure it
# takes effect.
BEGIN {
    *CORE::GLOBAL::exit = sub {
        CORE::exit($_[0]) unless caller eq 'ExtUtils::Command';

        my $exit = $_[0] || 0;
        die "exit: $exit\n";
    };
}

use ExtUtils::Command ();
use Exporter;

@ISA       = qw(Exporter);
@EXPORT    = @ExtUtils::Command::EXPORT;
@EXPORT_OK = @ExtUtils::Command::EXPORT_OK;


use strict;

foreach my $func (@ExtUtils::Command::EXPORT,
                  @ExtUtils::Command::EXPORT_OK)
{
    no strict 'refs';
    *{$func} = sub {
        local @ARGV = @_;

        my $ret;
        eval {
            $ret = &{'ExtUtils::Command::'.$func};
        };
        if( $@ =~ /^exit: (\d+)\n$/ ) {
            $ret = !$1;
        }
        elsif( $@ ) {
            die $@;
        }
        else {
            $ret = 1 unless defined $ret and length $ret;
        }

        return $ret;
    };
}


1;


__END__