File Coverage

blib/lib/Shell/Autobox.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	9	10	90.0
condition	4	8	50.0
subroutine	9	9	100.0
pod			n/a
total	63	68	92.6

package Shell::Autobox;

use strict;
use warnings;

use base qw(autobox);

use Carp qw(confess);
use IPC::Run3 qw(run3);

# XXX this declaration must be on a single line
# https://metacpan.org/pod/version#How-to-declare()-a-dotted-decimal-version
use version; our $VERSION = version->declare('v1.0.0');

sub import {
    my $class  = shift;
    my $caller = (caller)[0];

    for my $program (@_) {
        my $sub = sub {
            my $input = shift;
            my $args = join ' ', @_;
            my $maybe_args = length($args) ? " $args" : '';
            my $command = "$program$maybe_args";
            my $stdin = (defined($input) && length($input)) ? \$input : undef;

            run3($command, $stdin, \my $stdout, \my $stderr, {
                return_if_system_error => 1,
            });

            my $error = (defined($stderr) && $stderr =~ /\S/) ? ": $stderr" : '';
            my $message = "$command$error";

            if ($?) {
                confess "can't exec $message";
            } elsif ($error) {
                warn "error running $message";
            }

            return $stdout || '';
        };

        {
            no strict 'refs';
            *{"$caller\::$program"} = $sub;
        }
    }

    $class->SUPER::import(SCALAR => $caller);
}

1;

__END__