File Coverage

blib/lib/Set/Similarity/CosinePDL.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch			n/a
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	57	57	100.0

package Set::Similarity::CosinePDL;

use strict;
use warnings;

use namespace::autoclean;

use PDL;

use parent 'Set::Similarity';

our $VERSION = '0.014';

sub from_sets {
  my ($self, $set1, $set2) = @_;
  $self->_make_elem_list($set1,$set2);

  return $self->_cosine(
	norm($self->_make_vector( $set1 )),
	norm($self->_make_vector( $set2 ))
  );
}

sub _make_vector {
  my ( $self, $tokens ) = @_;
  my %elements = $self->_get_elements( $tokens );
  my $vector = zeroes $self->{'elem_count'};

  for my $key ( keys %elements ) {
	my $value = $elements{$key};
	my $offset = $self->{'elem_index'}->{$key};
	index( $vector, $offset ) .= $value;
  }
  return $vector;
}

sub _get_elements {
  my ( $self, $tokens ) = @_;
  my %elements;
  do { $_++ } for @elements{@$tokens};
  return %elements;
}

sub _make_elem_list {
  my ( $self,$tokens1,$tokens2 ) = @_;
  my %all_elems;
  for my $tokens ( $tokens1,$tokens2 ) {
	my %elements = $self->_get_elements( $tokens );
	for my $key ( keys %elements ) {
	  $all_elems{$key} += $elements{$key};
	}
  }

  # create a lookup hash
  my %lookup;
  my @sorted_elems = sort keys %all_elems;
  @lookup{@sorted_elems} = (0..scalar(@sorted_elems)-1 );

  $self->{'elem_index'} = \%lookup;
  $self->{'elem_list'} = \@sorted_elems;
  $self->{'elem_count'} = scalar @sorted_elems;
}

# Assumes both incoming vectors are normalized
sub _cosine {
  my ( $self, $vec1, $vec2 ) = @_;
  my $cos = inner( $vec1, $vec2 );	# inner product
  return $cos->sclr();  # converts PDL object to Perl scalar
}

1;


__END__