File Coverage

lib/Set/Light.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	7	8	87.5
condition			n/a
subroutine	11	11	100.0
pod	7	7	100.0
total	62	63	98.4

package Set::Light;

# ABSTRACT: (memory efficient) unordered set of strings

require 5.006;

use strict;
use warnings;

use Array::RefElem ();

our $VERSION = '0.95';


# shared undef variable
my $UNDEF = undef;

BEGIN {
    # handy aliases
    *has      = \&exists;
    *contains = \&exists;
    *is_null  = \&is_empty;
    *remove   = \&delete;
}


sub new {
    my $class = shift;
    my $x     = bless {}, $class;

    my $opt;
    $opt = shift if ref( $_[0] ) eq 'HASH';

    $x->insert(@_) if @_ != 0;

    $x;
}


sub insert {
    my $x = shift;

    # Note: this trick may no longer be necessesary for modern perls,
    # when storing an undef value.

    my $inserted = 0;
    for (@_) {
        $inserted++, Array::RefElem::hv_store( %$x, $_, $UNDEF )
          unless CORE::exists $x->{$_};
    }
    $inserted;
}


sub is_empty {
    my ($x) = @_;

    scalar keys %$x == 0;
}


sub size {
    my ($x) = @_;

    scalar keys %$x;
}


sub exists {
    my ( $x, $key ) = @_;

    CORE::exists $x->{$key};
}


sub delete {
    my $x = shift;

    my $deleted = 0;
    for (@_) {
        $deleted++, delete $x->{$_} if CORE::exists $x->{$_};
    }
    $deleted;
}


sub members {
    my ($x) = @_;
    return keys %$x;
}


1;

__END__