File Coverage

blib/lib/Search/Elasticsearch/Transport.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	6	6	100.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	55	55	100.0

# Licensed to Elasticsearch B.V under one or more agreements.
# Elasticsearch B.V licenses this file to you under the Apache 2.0 License.
# See the LICENSE file in the project root for more information

package Search::Elasticsearch::Transport;
$Search::Elasticsearch::Transport::VERSION = '7.717';
use Moo;

use URI();
use Time::HiRes qw(time);
use Try::Tiny;
use Search::Elasticsearch::Util qw(upgrade_error);
use namespace::clean;

with 'Search::Elasticsearch::Role::Is_Sync',
    'Search::Elasticsearch::Role::Transport';

#===================================
sub perform_request {
#===================================
    my $self   = shift;
    my $params = $self->tidy_request(@_);
    my $pool   = $self->cxn_pool;
    my $logger = $self->logger;

    my ( $code, $response, $cxn, $error );

    try {
        $cxn = $pool->next_cxn;
        my $start = time();
        $logger->trace_request( $cxn, $params );

        ( $code, $response ) = $cxn->perform_request($params);
        $pool->request_ok($cxn);
        $logger->trace_response( $cxn, $code, $response, time() - $start );
    }
    catch {
        $error = upgrade_error(
            $_,
            {   request     => $params,
                status_code => $code,
                body        => $response
            }
        );
    };

    if ($error) {
        if ( $pool->request_failed( $cxn, $error ) ) {
            $logger->debugf( "[%s] %s", $cxn->stringify, "$error" );
            $logger->info('Retrying request on a new cxn');
            return $self->perform_request($params);
        }

        $logger->trace_error( $cxn, $error );
        $error->is('NoNodes')
            ? $logger->throw_critical($error)
            : $logger->throw_error($error);
    }

    return $response;
}

1;

#ABSTRACT: Provides interface between the client class and the Elasticsearch cluster

__END__