File Coverage

blib/lib/SPOPS/Secure/Util.pm

Criterion	Covered	Total	%
statement	12	33	36.3
branch	0	14	0.0
condition	0	16	0.0
subroutine	4	6	66.6
pod	0	2	0.0
total	16	71	22.5

package SPOPS::Secure::Util;

# $Id: Util.pm,v 1.6 2004/06/02 00:48:24 lachoy Exp $

use strict;
use Data::Dumper  qw( Dumper );
use Log::Log4perl qw( get_logger );
use SPOPS::Secure qw( :level :scope );

my $log = get_logger();

# Setup a hashref where w/u => security_level and g points to a
# hashref where the key is the group_id value is the security level.

sub parse_objects_into_hashref {
    my ( $class, $security_objects ) = @_;

    my %items = ( SEC_SCOPE_WORLD() => undef,
                  SEC_SCOPE_USER()  => undef,
                  SEC_SCOPE_GROUP() => {} );
    unless ( ref $security_objects eq 'ARRAY'
             and scalar @{ $security_objects } > 0 ) {
        return undef;
    }

ITEM:
    foreach my $sec ( @{ $security_objects } ) {
        if ( $sec->{scope} eq SEC_SCOPE_WORLD || $sec->{scope} eq SEC_SCOPE_USER ) {
            $items{ $sec->{scope} } = $sec->{security_level};
            $log->is_debug &&
                $log->debug( "Assign [$sec->{security_level}] to [$sec->{scope}]" );
        }
        elsif ( $sec->{scope} eq SEC_SCOPE_GROUP ) {
            $items{ $sec->{scope} }->{ $sec->{scope_id} } = $sec->{security_level};
            $log->is_debug &&
                $log->debug( "Assign [$sec->{security_level}] to ",
                            "[$sec->{scope}][$sec->{scope_id}]" );
        }
    }
    $log->is_info &&
        $log->info( "All security parsed: ", Dumper( \%items ) );;
    return \%items;
}

sub find_class_and_oid {
    my ( $class, $item, $p ) = @_;

    # First assume it's a class we're passed in to check

    my $obj_class = $p->{class} || $item;
    my $oid       = $p->{object_id} || $p->{oid} || '0';

    # If this is an object, modify lines accordingly

    if ( ref $item and UNIVERSAL::can( $item, 'id' ) ) {
        $oid        = eval { $item->id } || '0';
        $obj_class  = ref $item;
    }
    return ( $obj_class, $oid );
}


1;

__END__