File Coverage

blib/lib/SMS/Send/IN/NICSMS.pm

Criterion	Covered	Total	%
statement	29	79	36.7
branch	4	36	11.1
condition	0	3	0.0
subroutine	8	13	61.5
pod	2	2	100.0
total	43	133	32.3

package SMS::Send::IN::NICSMS;

# ABSTRACT: SMS::Send driver to send messages via NIC's SMS Gateway ( https://smsgw.sms.gov.in )

use 5.006;
use strict;
use warnings;
use LWP::UserAgent;
use URI::Escape;

use base 'SMS::Send::Driver';

our $VERSION = '1.00'; # VERSION
our $AUTHORITY = 'cpan:INDRADG'; # AUTHORITY

sub new {
    my ( $class, %args ) = @_;

    # check we have the necessary credentials parameters
    die "Username needs to be passed as 'username'" unless ( $args{_login}  );
    die "PIN / password needs to be passed as 'password'" unless ( $args{_password} );
    die "SenderID / DLT Header needs to be passsed as 'signature'" unless ( $args{_signature} );
    die "19-digit DLT Entity ID needs to be passed as 'dlt_entity_id'" unless ( $args{_dlt_entity_id} );

    # build the object
    my $self = bless {
        _endpoint  => 'https://smsgw.sms.gov.in/failsafe/HttpLink',
        _debug     => 0,
        %args
    }, $class;

    # get an LWP user agent ready
    # FIXME - bypassing SSL cert check due to NIC's cert chain borkage
    $self->{ua} = LWP::UserAgent->new;
    $self->{ua}->ssl_opts(
        SSL_verify_mode => 0,
        verify_hostname => 0,
    );

    return $self;
}

sub _send_method {
    my ( $self, @args ) = @_;

    my @params;
    while (@args) {
        my $key = shift @args;
        my $val = shift @args;
        push( @params, join( '=', uri_escape($key), uri_escape($val) ) );
        print STDERR ">>>   Arg $key = $val\n" if ( $self->{_debug} );
    }
    my $url = join( '?', $self->{_endpoint}, join( '&', @params ) );
    print STDERR ">>>   GET $url\n" if ( $self->{_debug} );

    my $res = $self->{ua}->get($url);

    my $errorbroker = $self->_ERRORHANDLER ( $res );

    if ( $errorbroker ) {
        print STDERR "<<<   Message sent successfully\n";
        print STDERR "<<<   SMS gateway response : $res->{_content}\n" if ( $self->{_debug} );
        return 1;
    } else {
        print STDERR "<<<   Message send failed\n";
        print STDERR "<<<   SMS gateway response : $res->{_content}\n";
        return;
    }
}

sub send_sms {

    my ( $self, %args ) = @_;

    # FIXME : ugly hack to handle passing the DLT_TEMPLATE_ID for Koha ILS
    if  ( exists $self->{_iskohainstance} ) {
        if ( $self->{_iskohainstance} eq "yes" ) {
            # check if $args{text} is carrying the DLT_TEMPLATE_ID at the start of the message
            # else throw an error
            # As on date the IDs are 19 digit numbers

            die "19-digit DLT_TEMPLATE_ID not found at start of message!" unless ( $args{text} =~ /^\d{19}/ );

            $self->{_dlt_template_id} = substr( $args{text}, 0, 19);

            $args{text} =~ s!^\d{19}!!;
	} else {
            die "Incorrect value for the key 'iskohainstance' in IN/NICSMS.yaml. Check file!";
        }
    } else {
        $self->{_dlt_template_id} = $args{_dlt_template_id};
    }

    # check for message for 160 char limit
    my $text = $self->_MESSAGETEXT ( $args{text} );

    # check destination number for well-formedness under NNP 2003 schema
    my $to = $self->_TO ( $args{to} );

    $self->_send_method(
        username        => $self->{_login},
        pin             => $self->{_password},
        mnumber         => $args{to},
        message         => $args{text},
	signature       => $self->{_signature},
        dlt_entity_id   => $self->{_dlt_entity_id},
        dlt_template_id => $self->{_dlt_template_id},
    );
}

# -----------------------------------------------------
# internal sanitization routines
# -----------------------------------------------------

sub _MESSAGETEXT {
  my ( $self, $text ) = @_;
  use bytes;
  die "Message length over limit. Max length is 160 characters" unless ( length($text) <= 160 );
} # check for 160 char length of message text

# As per National Numbering Plan 2003, Indian mobile phone numbers have to be in
# [9|8|7]XXXXXXXXX format. So we need to sanitize our input. The driver expects
# number string in 91XXXXXXXXXX format

sub _TO {
  my ( $self, $dest ) = @_;

  my $checkseries;
  my $countrycode;

  # strip out any NaN characters
  $dest =~ s/[^\d]//g;

  # strip leading zero as some have the habit of inputing numbers as 0XXXXXXXXXX
  $dest =~ s/^0+//g;

  # check destination number length and format for well-formedness and fix common issues.
  if ( length($dest) == 12 or length($dest) == 10 ) {
  	if ( length($dest) == 12 ) {
	    $countrycode = substr $dest, 0, 2;
	    die "Country code incorrect, needs to be 91 for India" unless ( $countrycode eq '91' );
        }
	if ( length($dest) == 10 ) {
	    $countrycode = "91";
	    $dest = $countrycode . $dest;	#bring it up to 91XXXXXXXXXX
	}

	# check for 9,8,7,6 series numbering under NNP 2003
        # see https://en.wikipedia.org/wiki/Mobile_telephone_numbering_in_India
        #
        $checkseries = substr $dest, 2, 1;
        die "Invalid phone number as per National Numbering Plan 2003" unless ( $checkseries =~ /[9|8|7|6]/ );
  } else {
        die "Invalid phone number format";
  }
  return $dest;
}

sub _ERRORHANDLER {
  my ( $self, $res ) = @_;

  # check for "~code=API000 " in the response string signifying a successful send

  if ( $res->content =~ /~code=API000 / ) {
      return 1;
  } else {
      return;
  }
}

1;

__END__