File Coverage

blib/lib/SMS/Send/AT/SmsAt.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

package SMS::Send::AT::SmsAt;

use warnings;
use strict;
use Carp;
use LWP::UserAgent;
use XML::XPath;
use XML::Writer;
use SMS::Send::Driver;

use version; our $VERSION = qv('0.0.4');

use base 'SMS::Send::Driver';

sub new {
    my $proto = shift;
    my $class = ref $proto || $proto;
    my $self = { @_ };

    $self->{"_$_"} or croak "no $_ specified" for qw(login password);

    return bless $self, $class;
}

sub send_sms {
    my $self = shift;
    my %params = @_;

    croak 'no recipient specified' unless $params{to};
    $params{to} =~ s/\A\+//;
    $params{to} =~ s/\A0/43/; # Austria as default country

    my $text = unpack 'H*', $params{text} or croak 'no message specified';

    my $ua = LWP::UserAgent->new();
    my $message;
    my $writer = XML::Writer->new(OUTPUT => \$message, DATA_MODE => 1, DATA_INDENT => 4);

    $writer->xmlDecl();
    $writer->startTag('Request');
        $writer->dataElement('AccountLogin', $self->{_login}, Type => 'email');
        $writer->dataElement('AccountPass', $self->{_password});

        $writer->startTag('Message', Type => 'MTSMS');
            $writer->startTag('Recipients');
                $writer->dataElement('Recipient', $params{to}, Type => 'International');
            $writer->endTag('Recipients');

            $writer->dataElement('Text', $text, AutoSegment => 'simple');
        $writer->endTag('Message');
    $writer->endTag('Request');
    $writer->end();

    my $response = $ua->post('http://gateway.sms.at/xml_interface/', 'Content-type' => 'text/xml', Content => $message);
    if ($response->is_success) {
#        warn $response->content;  # or whatever
        my $xp = XML::XPath->new(xml => $response->content);
        my $code = $xp->getNodeText('/Response/Code');
        # stringify the XML::XPath::Literal object we just got for comparison
        return 1 if "$code" == 2000 or "$code" == 2001; # success
        warn $code . ': ' . $xp->getNodeText('/Response/CodeDescription');
        return 0;
    }
    else {
        Carp::croak($response->status_line);
    }

    return 1;
}


1; # Magic true value required at end of module
__END__