File Coverage

blib/lib/Rose/DBx/Role/QueryCannery.pm

Criterion	Covered	Total	%
statement	23	24	95.8
branch	1	2	50.0
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	33	35	94.2

#!perl
#
# $Id$

use strict;
use warnings;

package Rose::DBx::Role::QueryCannery;

our ($VERSION) = '1.00';

use Module::Runtime qw( use_module );
use MooX::Role::Parameterized;

sub _load_if {
    my $pkg = shift;
    no strict 'refs';
    return $pkg if keys %{ $pkg . '::' };
    use_module($pkg);
}

use Moo::Role 2;

role {
    my $params = shift;

    my ( $canning_class, %datasource );

    if ( $params->{query_class} ) {
        $canning_class = _load_if( $params->{query_class} );
    }
    else {
        # We know these are in their own files, so we can use_module directly
        $canning_class =
          eval { use_module('Rose::DBx::CannedQuery::Glycosylated') }
          || use_module('Rose::DBx::CannedQuery');
    }

    foreach my $key (qw/ rdb rdb_class rdb_params /) {
        next unless $params->{$key};
        $datasource{$key} = $params->{$key};
        _load_if( $params->{$key} ) if $key eq 'rdb_class';
    }

    my $log_args = sub { return (); };
    if ( $canning_class->can('verbose') and $canning_class->can('logger') ) {
        $log_args = sub {
            my $consumer = shift;
            my (@args);
            push @args, verbose => $consumer->verbose || 0
              if $consumer->can('verbose');
            push @args, logger => $consumer->logger
              if $consumer->can('logger') && $consumer->logger;
            return @args;
        };
    } ## end if ( $canning_class->can...)

    my $create_query = sub {
        my ( $constructor, $obj, $sql, $opts ) = @_;
        $opts ||= {};
        my (%merged_args) = (
            $log_args->($obj),
            %datasource,
            sql => $sql,
            %$opts
        );
        return $canning_class->$constructor(%merged_args);
    };

    method 'build_query' => sub { $create_query->( 'new',           @_ ); };
    method 'get_query'   => sub { $create_query->( 'new_or_cached', @_ ); };

};

1;

__END__