File Coverage

blib/lib/Rose/DBx/Object/InternalPager.pm

Criterion	Covered	Total	%
statement	9	43	20.9
branch	0	16	0.0
condition			n/a
subroutine	3	7	42.8
pod	0	3	0.0
total	12	69	17.3

###########################################
package Rose::DBx::Object::InternalPager;
###########################################
use strict;
use warnings;
use Log::Log4perl qw(:easy);

our $VERSION = "0.03";

###########################################
sub new {
###########################################
    my($class, %options) = @_;

    my $self = {
        %options,
    };

    $self->{pager_options}->{per_page} = 50 unless defined
        $self->{pager_options}->{per_page};

    $self->{pager_options}->{start_page} = 1 unless defined
        $self->{pager_options}->{start_page};

    for my $param (qw(manager_options class_name manager_method)) {
        if(!defined $options{ $param}) {
            LOGDIE "Missing mandatory paramter $param";
        }
    }

    bless $self, $class;

    $self->{pager} = $self->make_pager(
        $self->{ class_name },
        $self->{ manager_method },
        $self->{ pager_options },
        $self->{ manager_options },
    );

    return $self;
}

###########################################
sub next {
###########################################
    my($self) = @_;

    return $self->{pager}->();
}

###########################################
sub make_pager {
###########################################
    my($self, $class, $method, $options, $moptions) = @_;

    $options  = {} unless $options;
    $moptions = {} unless $moptions;

    my $manager_class   = "${class}::Manager";
    my $iterator_method = "${method}_iterator";

    my $per_page        = $options->{per_page};
    my $page            = $options->{start_page};
    my $page_items_done = 0;

    if(!defined $per_page) {
       LOGDIE "Parameter per_page not defined";
    }
    if(!defined $page) {
       LOGDIE "Parameter start_page not defined";
    }

    DEBUG "Creating first pager iterator ",
          "class=$class per_page=$per_page";

    my $itr = $manager_class->$iterator_method(
        page     => $page,
        per_page => $per_page,
        %$moptions,
    );

    return sub {

        if($page_items_done == $per_page) {
            # Page done? Get next iterator.
            $page++;
            DEBUG "Getting next iterator for ",
                  "class=$class (page=$page)";

            $itr = $manager_class->$iterator_method(
                page     => $page,
                per_page => $per_page,
                %$moptions);

            $page_items_done = 0;
        }

        $page_items_done++;

        return $itr->next();
    }
}

1;

__END__