File Coverage

blib/lib/Rose/DBx/CannedQuery/Glycosylated.pm

Criterion	Covered	Total	%
statement	55	55	100.0
branch	16	16	100.0
condition	6	8	75.0
subroutine	10	10	100.0
pod	3	3	100.0
total	90	92	97.8

#!perl
#

use strict;
use warnings;

package Rose::DBx::CannedQuery::Glycosylated;

our ($VERSION) = '1.01';

use Carp;
use Scalar::Util;

use Moo 2;
use Types::Standard qw/ Str /;

extends 'Rose::DBx::CannedQuery';
with 'MooX::Role::Chatty';

has 'name' => ( is => 'ro', isa => Str, lazy => 1, builder => '_build_name' );

sub _build_name {
    my $self = shift;
    substr( $self->sql, 0, 32 );
}

sub do_one_query_ref {
    my ( $self, $bind_vals, $opts ) = @_;
    $bind_vals ||= [];
    $opts ||= [ {} ];
    $opts = [ {}, $opts ] unless ref $opts;
    my $verbose = $self->verbose;
    my ($rslt);

    if ( $verbose > 2 ) {
        require Data::Dumper;
        my $optstr = Data::Dumper->new($opts)->Terse(1)->Pad("\t")->Dump;
        $optstr =~ s/\n+$//;
        $optstr =~ s/\n\s*/, /g;
        $self->remark(
                'Executing '
              . $self->name
              . (
                @$bind_vals
                ? " with bind values:\n"
                  . join( "\n", map { "\t$_" } @$bind_vals ) . "\n"
                : ' '
              )
              . "with query modifiers:\n$optstr"
        );
    }

    $rslt = $self->resultref( $bind_vals, $opts );
    $self->remark( 'Got ' . scalar(@$rslt) . ' results' ) if $verbose > 2;

    return $rslt;
}

sub do_one_query {
    return @{ shift->do_one_query_ref( \@_ ) };
}

sub do_many_queries {
    my ( $self, $param_sets ) = @_;
    $param_sets ||= [ [] ];
    my $array_of_sets = Scalar::Util::reftype($param_sets) eq 'ARRAY';
    my $verbose       = $self->verbose;
    my (%rslt);

    if ($array_of_sets) {
        my $i = 'Element0000';
        $param_sets = { map { $i++ => $_ } @$param_sets };
    }

    foreach my $bind_name ( sort keys %$param_sets ) {
        my $bind_vals = $param_sets->{$bind_name} || [];
        $self->remark(
            "Executing bind set $bind_name for query " . $self->name )
          if $verbose > 1;
        if ( ref $bind_vals->[0] eq 'ARRAY' ) {

            # We actually have a tuple of $bind_values, $fetch_values
            $rslt{$bind_name} = $self->do_one_query_ref(@$bind_vals);
        }
        else {
            # Just plain old bind values; don't dereference further
            $rslt{$bind_name} = $self->do_one_query_ref($bind_vals);
        }
    }

    return $array_of_sets
      ? [ map { $rslt{$_} } sort keys %rslt ]
      : \%rslt;
}

1;

__END__