File Coverage

lib/Rex/Hook/File/Impostor.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	2	2	100.0
condition			n/a
subroutine	12	12	100.0
pod	0	3	0.0
total	58	61	95.0

package Rex::Hook::File::Impostor;

# ABSTRACT: execute Rex file management commands on a copy of the managed path

use 5.012;
use warnings;

use Digest::MD5;
use English qw( -no_match_vars );
use File::Basename;
use File::Spec;
use Rex 1.013004 -base;
use Rex::Hook;
use Sys::Hostname;

our $VERSION = 'v0.2.0';

register_function_hooks { before => { file => \&impostor_hook, }, };

sub impostor_hook {
    my ( $managed_path, @opts ) = @_;

    my $impostor_path = get_impostor_for($managed_path);

    mkdir dirname($impostor_path);

    if ( is_file($managed_path) ) {
        Rex::Logger::debug("Copying $managed_path to $impostor_path");
        cp $managed_path, $impostor_path;
    }

    return $impostor_path, @opts;
}

sub get_impostor_for {
    my $path = shift;

    my ( $volume, $directories, $file ) = File::Spec->splitpath($path);
    $volume =~ s/://gmsx;

    return File::Spec->join( get_impostor_directory(), $volume, $directories,
        $file );
}

sub get_impostor_directory {
    my $hasher = Digest::MD5->new();

    $hasher->add(hostname);
    $hasher->add($PID);

    my $unique_id = $hasher->hexdigest();

    my $impostor_directory = File::Spec->join( Rex::Config->get_tmp_dir(),
        'rex_hook_file_impostor', $unique_id );

    mkdir $impostor_directory;
    return $impostor_directory;
}

1;

__END__