File Coverage

lib/Rex/Inventory/Hal/Object.pm

Criterion	Covered	Total	%
statement	28	60	46.6
branch	2	12	16.6
condition	0	3	0.0
subroutine	7	13	53.8
pod	0	5	0.0
total	37	93	39.7

#
# (c) Jan Gehring
#

package Rex::Inventory::Hal::Object;

use v5.12.5;
use warnings;

our $VERSION = '1.14.2.3'; # TRIAL VERSION

sub new {
  my $that  = shift;
  my $proto = ref($that) || $that;
  my $self  = {@_};

  bless( $self, $proto );

  return $self;
}

sub has {

  my ( $class, $keys ) = @_;
  for my $k ( @{$keys} ) {
    my $key       = $k->{key};
    my $accessor  = $k->{accessor};
    my $overwrite = $k->{overwrite};

    no strict 'refs';
    if ( !$overwrite ) {
      *{"${class}::get_$accessor"} = sub {
        my ($self) = @_;
        if ( $k->{"parent"} ) {
          return $self->parent()->get($key);
        }
        else {
          if ( ref($key) eq "ARRAY" ) {
            for my $_k ( @{$key} ) {
              if ( my $ret = $self->get($_k) ) {
                return $ret;
              }

              return "";
            }
          }
          else {
            return $self->get($key);
          }
        }
      };

    }
    push( @{"${class}::items"}, $k );

    use strict;
  }

}

# returns the parent of the current object
sub parent {

  my ($self) = @_;
  return $self->{"hal"}->get_object_by_udi( $self->{'info.parent'} );

}

sub get {

  my ( $self, $key ) = @_;

  if ( ref( $self->{$key} ) eq "ARRAY" ) {
    return @{ $self->{$key} };
  }

  return exists $self->{$key}
    ? $self->{$key}
    : "";

}

sub get_all {

  my ($self) = @_;

  my $r = ref($self);

  no strict 'refs';
  my @items = @{"${r}::items"};
  use strict;

  my $ret;
  for my $itm (@items) {
    my $f = "get_" . $itm->{"accessor"};
    $ret->{ $itm->{"accessor"} } = $self->$f();
  }

  return $ret;
}

1;