File Coverage

blib/lib/Retry/Backoff.pm

Criterion	Covered	Total	%
statement	72	76	94.7
branch	25	30	83.3
condition	4	6	66.6
subroutine	9	9	100.0
pod	1	3	33.3
total	111	124	89.5

package Retry::Backoff;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2021-08-06'; # DATE
our $DIST = 'Retry-Backoff'; # DIST
our $VERSION = '0.003'; # VERSION

use 5.010001;
use strict 'subs', 'vars';
use warnings;
use Log::ger;

use Time::HiRes qw(time);

use Exporter 'import';
our @EXPORT_OK = qw(retry);

sub new {
    my $class = shift;
    my %args = @_;

    my $self = {};

    $self->{strategy} = delete $args{strategy};
    unless ($self->{strategy}) {
        $self->{strategy} = 'Exponential';
        $args{initial_delay} //= 1;
        $args{max_attempts}  //= 10;
        $args{max_delay}     //= 300;
    }
    $self->{on_failure}   = delete $args{on_failure};
    $self->{on_success}   = delete $args{on_success};
    $self->{retry_if}     = delete $args{retry_if};
    $self->{non_blocking} = delete $args{non_blocking};
    $self->{attempt_code} = delete $args{attempt_code};

    my $ba_mod = "Algorithm::Backoff::$self->{strategy}";
    (my $ba_mod_pm = "$ba_mod.pm") =~ s!::!/!g;
    require $ba_mod_pm;
    $self->{_backoff} = $ba_mod->new(%args);

    bless $self, $class;
}

sub run {
    my $self = shift;

    my @attempt_result;
    my $attempt_result;
    my $wantarray = wantarray;

    while(1) {
        if (my $timestamp = $self->{_needs_sleeping_until}) {
            # we can't retry until we have waited enough time
            my $now = time();
            $now >= $timestamp or return;
            $self->{_needs_sleeping_until} = 0;
        }

        # run the code, capture the error
        my $error;
        if ($wantarray) {
            $wantarray = 1;
            @attempt_result = eval { $self->{attempt_code}->(@_) };
            $error = $@;
        } elsif (!defined $wantarray) {
            eval { $self->{attempt_code}->(@_) };
            $error = $@;
        } else {
            $attempt_result = eval { $self->{attempt_code}->(@_) };
            $error = $@;
        }

        my $h = {
            error => $error,
            action_retry => $self,
            attempt_result =>
                ( $wantarray ? \@attempt_result : $attempt_result ),
            attempt_parameters => \@_,
        };

        if ($self->{retry_if}) {
            $error = $self->{retry_if}->($h);
        }

        my $delay;
        my $now = time();
        if ($error) {
            $self->{on_failure}->($h) if $self->{on_failure};
            $delay = $self->{_backoff}->failure($now);
        } else {
            $self->{on_success}->($h) if $self->{on_success};
            $delay = $self->{_backoff}->success($now);
        }

        if ($delay == -1) {
            last;
        } elsif ($self->{non_blocking}) {
            $self->{_needs_sleeping_until} = $now + $delay;
        } else {
            sleep $delay;
        }

        last unless $error;
    }

    return $wantarray ? @attempt_result : $attempt_result;
}


sub retry (&;@) {
    my $code = shift;
    @_ % 2
        and die "Arguments to retry must be a CodeRef, and an even number of key / values";
    my %args = @_;
    __PACKAGE__->new(attempt_code => $code, %args)->run();
}

1;
# ABSTRACT: Retry a piece of code, with backoff strategies

__END__