File Coverage

blib/lib/Range/HandleIter.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	19	20	95.0
condition	4	5	80.0
subroutine	8	8	100.0
pod	1	1	100.0
total	76	78	97.4

package Range::HandleIter;

our $DATE = '2019-05-12'; # DATE
our $VERSION = '0.001'; # VERSION

use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(range_handleiter);

sub range_handleiter($$;$) {
    my ($start, $end, $step) = @_;

    tie *FH, 'Range::HandleIter::Tie', $start, $end, $step;
    \*FH;
}

package # hide from PAUSE
    Range::HandleIter::Tie;

use Scalar::Util qw(looks_like_number);

sub TIEHANDLE {
    my $class = shift;
    my ($start, $end, $step) = @_;
    $step //= 1;

    my $self = {
        start => $start,
        end   => $end,
        step  => $step,

        _ended => 0,
        _len   => 0,
        _cur   => $start,
        _buf   => [],
    };

    if (looks_like_number($start) && looks_like_number($end)) {
        $self->{_num}   = 1;
        $self->{_ended}++ if $start > $end;
    } else {
        die "Cannot specify step != 1 for non-numeric range" if $step != 1;
        $self->{_ended}++ if $start gt $end;
    }
    bless $self, $class;
}

sub _next {
    my $self = shift;

    if ($self->{_num}) {
        $self->{_ended}++ if $self->{_cur} > $self->{end};
        return if $self->{_ended};
        push @{ $self->{_buf} }, $self->{_cur};
        $self->{_cur} += $self->{step};
    } else {
        return if $self->{_ended};
        $self->{_ended}++ if $self->{_cur} ge $self->{end};
        push @{ $self->{_buf} }, $self->{_cur}++;
    }
}

sub READLINE {
    my $self = shift;
    $self->_next;
    if (@{ $self->{_buf} }) {
        $self->{_len}++;
        shift @{ $self->{_buf} };
    } else {
        undef;
    }
}

1;
# ABSTRACT: Generate a tied-handle iterator for range

__END__